games-strategy/hedgewars/hedgewars-1.0.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 CMAKE_MAKEFILE_GENERATOR=emake
   7 inherit cmake xdg-utils
   8
   9 MY_P=${PN}-src-${PV}
  10
  11 DESCRIPTION="A turn-based strategy, artillery, action and comedy game"
  12 HOMEPAGE="https://www.hedgewars.org/"
  13 SRC_URI="https://www.hedgewars.org/download/releases/${MY_P}.tar.bz2"
  14
  15 LICENSE="GPL-2 Apache-2.0 FDL-1.3"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="server"
  19
  20 QA_FLAGS_IGNORED="/usr/bin/hwengine" # pascal sucks
  21 QA_PRESTRIPPED="/usr/bin/hwengine" # pascal sucks
  22
  23 # qtcore:5= - depends on private header
  24 DEPEND="
  25         >=dev-games/physfs-3.0.1
  26         dev-lang/lua:0=
  27         dev-qt/qtcore:5=
  28         dev-qt/qtgui:5
  29         dev-qt/qtnetwork:5
  30         dev-qt/qtwidgets:5
  31         media-libs/libpng:0=
  32         media-libs/libsdl2:=
  33         media-libs/sdl2-image:=
  34         media-libs/sdl2-mixer:=[vorbis]
  35         media-libs/sdl2-net:=
  36         media-libs/sdl2-ttf:=
  37         sys-libs/zlib
  38         !x86? ( media-video/ffmpeg:= )
  39         "
  40 RDEPEND="${DEPEND}
  41         app-arch/xz-utils
  42         >=media-fonts/dejavu-2.28
  43         media-fonts/wqy-zenhei"
  44 BDEPEND="
  45         dev-qt/linguist-tools:5
  46         server? (
  47                 >=dev-lang/ghc-6.10
  48                 dev-haskell/entropy
  49                 dev-haskell/hslogger
  50                 >=dev-haskell/mtl-2
  51                 >=dev-haskell/network-2.3
  52                 dev-haskell/random
  53                 dev-haskell/regex-tdfa
  54                 dev-haskell/sandi
  55                 dev-haskell/sha
  56                 dev-haskell/vector
  57                 dev-haskell/utf8-string
  58                 dev-haskell/yaml
  59                 >=dev-haskell/zlib-0.5.3 <dev-haskell/zlib-0.6
  60         )
  61         !x86? ( >=dev-lang/fpc-2.4 )
  62         x86? (
  63                 >=dev-lang/ghc-6.10
  64                 dev-haskell/parsec
  65         )"
  66
  67 PATCHES=( "${FILESDIR}/${P}-qt-5.15.patch" )
  68
  69 S="${WORKDIR}"/${MY_P}
  70
  71 src_configure() {
  72         local mycmakeargs=(
  73                 -DMINIMAL_FLAGS=ON
  74                 -DDATA_INSTALL_DIR="${EPREFIX}/usr/share/${PN}"
  75                 -Dtarget_binary_install_dir="${EPREFIX}/usr/bin"
  76                 -Dtarget_library_install_dir="${EPREFIX}/usr/$(get_libdir)"
  77                 -DNOSERVER=$(usex !server)
  78                 -DBUILD_ENGINE_C=$(usex x86)
  79                 -DNOVIDEOREC=$(usex !x86)
  80                 -DCMAKE_VERBOSE_MAKEFILE=TRUE
  81                 # Need to tell the build system where the fonts are located
  82                 # as it uses PhysFS' symbolic link protection mode which
  83                 # prevents us from symlinking the fonts into the right directory
  84                 #   https://hg.hedgewars.org/hedgewars/rev/76ad55807c24
  85                 #   https://icculus.org/physfs/docs/html/physfs_8h.html#aad451d9b3f46f627a1be8caee2eef9b7
  86                 -DFONTS_DIRS="${EPREFIX}/usr/share/fonts/wqy-zenhei;${EPREFIX}/usr/share/fonts/dejavu"
  87                 # upstream sets RPATH that leads to weird breakage
  88                 # https://bugzilla.redhat.com/show_bug.cgi?id=1200193
  89                 -DCMAKE_SKIP_RPATH=ON
  90         )
  91         cmake_src_configure
  92 }
  93
  94 src_install() {
  95         cmake_src_install
  96         doman man/${PN}.6
  97 }
  98
  99 pkg_postinst() {
 100         xdg_desktop_database_update
 101 }
 102
 103 pkg_postrm() {
 104         xdg_desktop_database_update
 105 }