games-strategy/crimson/crimson-0.5.3-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit desktop
   6
   7 DESCRIPTION="Tactical war game in the tradition of Battle Isle"
   8 HOMEPAGE="http://crimson.seul.org/"
   9 SRC_URI="http://crimson.seul.org/files/${P}.tar.bz2"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="test zlib"
  15
  16 RDEPEND="
  17         media-libs/libsdl[sound,video]
  18         media-libs/sdl-mixer
  19         media-libs/sdl-ttf
  20         media-libs/sdl-net
  21         zlib? ( sys-libs/zlib )"
  22 DEPEND="${RDEPEND}
  23         dev-libs/libxslt
  24         test? (
  25                 app-text/docbook-xml-dtd:4.2
  26                 dev-libs/libxml2
  27         )
  28 "
  29
  30 src_configure() {
  31         econf \
  32                 --enable-sound \
  33                 --enable-network \
  34                 $(use_with zlib) \
  35                 --enable-cfed \
  36                 --enable-bi2cf \
  37                 --enable-comet \
  38                 --enable-cf2bmp
  39 }
  40
  41 src_install() {
  42         emake \
  43                 DESTDIR="${D}" \
  44                 pixmapsdir="/usr/share/pixmaps" \
  45                 install
  46         einstalldocs
  47         rm -rf "${ED}/usr/share/applications"
  48         make_desktop_entry crimson "Crimson Fields"
  49 }