games-rpg/eternal-lands/eternal-lands-1.9.5.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit desktop toolchain-funcs xdg
   6
   7 DESCRIPTION="A 3D fantasy MMORPG written in C and SDL"
   8 HOMEPAGE="http://www.eternal-lands.com"
   9 SRC_URI="https://github.com/raduprv/Eternal-Lands/archive/${PV}.tar.gz -> ${P}.tar.gz"
  10
  11 LICENSE="eternal_lands"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="doc"
  15
  16 RDEPEND="app-arch/unzip
  17         dev-libs/libxml2
  18         media-libs/cal3d[-16bit-indices]
  19         media-libs/freealut
  20         media-libs/libpng:0=
  21         media-libs/libsdl[X,opengl,video]
  22         media-libs/libvorbis
  23         media-libs/openal
  24         media-libs/sdl-image
  25         media-libs/sdl-net
  26         sys-libs/zlib[minizip]
  27         virtual/glu
  28         virtual/opengl
  29         x11-libs/libX11
  30         x11-libs/libXau
  31         x11-libs/libXdmcp
  32         x11-libs/libXext"
  33 DEPEND="${RDEPEND}
  34         media-libs/glew"
  35 BDEPEND="${DEPEND}
  36         virtual/pkgconfig
  37         doc? (
  38                 app-doc/doxygen
  39                 media-gfx/graphviz
  40         )"
  41
  42 S="${WORKDIR}/Eternal-Lands-${PV}"
  43
  44 PATCHES=(
  45         "${FILESDIR}/${PN}-1.9.5.3-build.patch"
  46         "${FILESDIR}/${PN}-1.9.5.3-minizip.patch"
  47 )
  48
  49 src_prepare() {
  50         default
  51
  52         sed -i "s/FEATURES/EL_FEATURES/g" make.defaults || die
  53         sed -i "s/FEATURES/EL_FEATURES/g" Makefile.linux || die
  54
  55         # Remove bundled minizip
  56         rm io/{crypt,ioapi,unzip,zip}.h || die
  57         rm io/{ioapi,unzip,zip}.c || die
  58
  59         cp Makefile.linux Makefile || die
  60 }
  61
  62 src_compile() {
  63         emake CC="$(tc-getCC)" CXX="$(tc-getCXX)"
  64         use doc && emake docs
  65 }
  66
  67 src_install() {
  68         dobin el.linux.bin
  69         newbin "${FILESDIR}"/el-wrapper el
  70         newicon -s 48 elc.png ${PN}.png
  71         make_desktop_entry el "Eternal Lands"
  72
  73         dodoc CHANGES TODO
  74         use doc && dodoc -r docs/html/
  75 }