games-roguelike/tomenet/tomenet-4.7.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit eutils gnome2-utils toolchain-funcs
   6
   7 DESCRIPTION="A MMORPG based on the works of J.R.R. Tolkien"
   8 HOMEPAGE="https://www.tomenet.eu"
   9 SRC_URI="https://www.tomenet.eu/downloads/${P}.tar.bz2"
  10
  11 LICENSE="Moria"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="dedicated server +sound X"
  15
  16 RDEPEND="sys-libs/ncurses:0
  17         !dedicated? (
  18                 X? (
  19                         x11-libs/libX11
  20                 )
  21                 sound? (
  22                         media-libs/libsdl[sound]
  23                         media-libs/sdl-mixer[vorbis,smpeg,mp3]
  24                 )
  25         )"
  26 DEPEND="${RDEPEND}
  27         virtual/pkgconfig
  28         !dedicated? ( sound? ( app-arch/p7zip[wxwidgets] ) )"
  29
  30 S=${WORKDIR}/${P}/src
  31
  32 PATCHES=(
  33         "${FILESDIR}"/${P}-makefile.patch
  34 )
  35
  36 src_prepare() {
  37         default
  38         use server || use dedicated || { rm -r ../lib/{config,data,save} || die ;}
  39
  40         sed \
  41                 -e "s#@LIBDIR@#/usr/share/${PN}#" \
  42                 "${FILESDIR}"/${PN}-wrapper > "${T}"/${PN} || die
  43
  44         if use server || use dedicated ; then
  45                 sed \
  46                         -e "s#@LIBDIR@#/usr/share/${PN}#" \
  47                         "${FILESDIR}"/${PN}-server-wrapper > "${T}"/${PN}.server || die
  48         fi
  49
  50         tc-export PKG_CONFIG
  51 }
  52
  53 src_compile() {
  54         local mytargets="$(usex dedicated "accedit tomenet.server" "$(usex server "all" "tomenet")")"
  55         emake \
  56                 $(usex dedicated "" "$(usex X "USE_X=1" "")") \
  57                 $(usex dedicated "" "$(usex sound "USE_SDL=1" "")") \
  58                 -f makefile \
  59                 ${mytargets[@]}
  60 }
  61
  62 src_install() {
  63         dodoc ../TomeNET-Guide.txt
  64
  65         if ! use dedicated ; then
  66                 newbin ${PN} ${PN}.bin
  67                 dobin "${T}"/${PN}
  68
  69                 doicon -s 48 client/tomenet4.png
  70                 make_desktop_entry ${PN} ${PN} ${PN}4
  71         fi
  72
  73         if use server || use dedicated ; then
  74                 newbin tomenet.server tomenet.server.bin
  75                 dobin "${T}"/${PN}.server accedit
  76         fi
  77
  78         insinto "/usr/share/${PN}"
  79         doins -r ../lib/*
  80         doins ../.tomenetrc
  81 }
  82
  83 pkg_preinst() {
  84         gnome2_icon_savelist
  85 }
  86
  87 pkg_postinst() {
  88         gnome2_icon_cache_update
  89
  90         if use sound; then
  91                 elog "You can get soundpacks from here:"
  92                 elog '  https://tomenet.net/downloads.php'
  93                 elog "They must be placed inside ~/.tomenet directory."
  94         fi
  95 }
  96
  97 pkg_postrm() {
  98         gnome2_icon_cache_update
  99 }