games-puzzle/xlogical/xlogical-1.0.7.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit autotools versionator eutils games
   7
   8 MY_PV=$(replace_version_separator 2 '-' )
   9 MY_P=${PN}-${MY_PV}
  10 DESCRIPTION="SDL logical clone"
  11 HOMEPAGE="http://changeling.ixionstudios.com/xlogical/"
  12 SRC_URI="http://changeling.ixionstudios.com/xlogical/downloads/${MY_P}.tar.bz2
  13         alt_gfx? ( http://changeling.ixionstudios.com/xlogical/downloads/xlogical_gfx.zip )"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="amd64 x86"
  18 IUSE="alt_gfx"
  19
  20 RDEPEND="media-libs/libsdl[sound,video]
  21         media-libs/sdl-image[jpeg]
  22         media-libs/sdl-mixer[mod]"
  23 DEPEND="${RDEPEND}
  24         alt_gfx? ( app-arch/unzip )"
  25
  26 S=${WORKDIR}/${PN}-$(get_version_component_range 1-2)
  27
  28 src_unpack() {
  29         unpack ${MY_P}.tar.bz2
  30         if use alt_gfx ; then
  31                 cd "${S}/images"
  32                 unpack xlogical_gfx.zip
  33         fi
  34 }
  35
  36 src_prepare() {
  37         sed -i '/^CXXFLAGS/d' Makefile.am || die
  38         edos2unix properties.h anim.h exception.h
  39         epatch \
  40                 "${FILESDIR}"/${P}-gcc41.patch \
  41                 "${FILESDIR}"/${P}-gcc43.patch
  42         mv configure.in configure.ac
  43         eautoreconf
  44 }
  45
  46 src_install() {
  47         dogamesbin ${PN}
  48
  49         insinto "${GAMES_DATADIR}"/${PN}
  50         doins -r ${PN}.{properties,levels} music sound images
  51         find "${D}" -name "Makefile*" -exec rm -f '{}' +
  52
  53         insinto "${GAMES_STATEDIR}"/${PN}
  54         doins ${PN}.scores
  55         fperms 0660 "${GAMES_STATEDIR}"/${PN}/${PN}.scores
  56
  57         dodoc AUTHORS ChangeLog NEWS README TODO
  58         make_desktop_entry ${PN} "Xlogical"
  59         prepgamesdirs
  60 }