games-puzzle/wizznic/wizznic-306.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit eutils games
   7
   8 DESCRIPTION="Block-clearing puzzle game"
   9 HOMEPAGE="http://wizznic.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/wizznic/Wizznic_src_build_${PV}.tar.bz2"
  11
  12 LICENSE="GPL-3"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15 IUSE=""
  16
  17 DEPEND="media-libs/libsdl[sound,joystick,video]
  18         media-libs/sdl-image[png]
  19         media-libs/sdl-mixer[vorbis]"
  20 RDEPEND=${DEPEND}
  21
  22 S=${WORKDIR}/Wizznic_src_build_${PV}
  23
  24 src_prepare() {
  25         sed \
  26                 -e '/^\(CC\|LD\|STRIP\)/d' \
  27                 -e 's/(LD)/(CC)/g' \
  28                 -e '/man1/s/1/6/g' \
  29                 -e '/CFLAGS.*=/d' \
  30                 Makefile.linux > Makefile || die
  31         mv doc/wizznic.1 doc/wizznic.6 || die
  32         sed -i \
  33                 -e '/Dt WIZZNIC/s/1/6/' \
  34                 doc/wizznic.6 || die
  35 }
  36
  37 src_compile() {
  38         emake \
  39                 DATADIR="${GAMES_DATADIR}/${PN}/" \
  40                 BINDIR="${GAMES_BINDIR}" \
  41                 STRIP=true
  42 }
  43
  44 src_install() {
  45         emake \
  46                 DESTDIR="${D}" \
  47                 DATADIR="${GAMES_DATADIR}/${PN}/" \
  48                 BINDIR="${GAMES_BINDIR}" \
  49                 install
  50         dodoc doc/{changelog.txt,credits.txt,media-licenses.txt,ports.txt,readme.txt}
  51         newicon data/wmicon.png ${PN}.png
  52         make_desktop_entry wizznic "Wizznic!"
  53         prepgamesdirs
  54 }