games-puzzle/ltris/ltris-1.0.19-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools desktop flag-o-matic
   6
   7 DESCRIPTION="Very polished Tetris clone"
   8 HOMEPAGE="http://lgames.sourceforge.net/LTris/"
   9 SRC_URI="mirror://sourceforge/lgames/${P}.tar.gz"
  10
  11 LICENSE="GPL-2+"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="nls"
  15
  16 RDEPEND="
  17         media-libs/libsdl[video]
  18         media-libs/sdl-mixer
  19         nls? ( virtual/libintl )
  20 "
  21 DEPEND="${RDEPEND}
  22         nls? ( sys-devel/gettext )
  23 "
  24
  25 src_prepare() {
  26         default
  27         eapply "${FILESDIR}"/${P}-gentoo.patch
  28         mv configure.in configure.ac || die
  29         AT_M4DIR=m4 eautoreconf
  30         append-cflags -std=gnu89 # build with gcc5 (bug #570966)
  31 }
  32
  33 src_configure() {
  34         econf $(use_enable nls)
  35 }
  36
  37 src_install() {
  38         default
  39         newicon icons/ltris48.xpm ${PN}.xpm
  40         make_desktop_entry ltris LTris
  41 }