games-puzzle/gemdropx/gemdropx-0.9-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit games
   6
   7 DESCRIPTION="A puzzle game where it's your job to clear the screen of gems"
   8 HOMEPAGE="http://www.newbreedsoftware.com/gemdropx/"
   9 SRC_URI="ftp://ftp.sonic.net/pub/users/nbs/unix/x/gemdropx/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE=""
  15
  16 DEPEND=">=media-libs/libsdl-1.2.3-r1[joystick,video]
  17         >=media-libs/sdl-mixer-1.2.1[mod]"
  18 RDEPEND="${DEPEND}"
  19
  20 src_prepare() {
  21         sed -i \
  22                 -e '/^CC/d' \
  23                 -e '/^CXX/d' \
  24                 -e 's/CXX/CC/' \
  25                 -e 's/-o/$(LDFLAGS) -o/' \
  26                 Makefile || die
  27
  28         find data/ -type d -name .xvpics -exec rm -rf \{\} +
  29 }
  30
  31 src_compile() {
  32         emake \
  33                 DATA_PREFIX="${GAMES_DATADIR}/${PN}" \
  34                 XTRA_FLAGS="${CFLAGS}"
  35 }
  36
  37 src_install() {
  38         dogamesbin gemdropx
  39         dodir "${GAMES_DATADIR}/${PN}"
  40         cp -r data/* "${D}/${GAMES_DATADIR}/${PN}/" || die
  41         dodoc AUTHORS.txt CHANGES.txt ICON.txt README.txt TODO.txt
  42         prepgamesdirs
  43 }