games-fps/prboom-plus/prboom-plus-2.5.1.5.4540.1.ebuild

   1 # Copyright 2019-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools desktop xdg
   7
   8 MY_PV=$(ver_rs 4 "+svn" 5 "+dfsg")
   9 MY_P=${PN}-${MY_PV}
  10 DESCRIPTION="An enhanced clone of the classic first-person shooter Doom"
  11 HOMEPAGE="http://prboom-plus.sourceforge.net"
  12 SRC_URI="http://deb.debian.org/debian/pool/main/p/prboom-plus/${PN}_${MY_PV}.orig.tar.xz -> ${P}.tar.xz"
  13
  14 LICENSE="GPL-2+ BSD BSD-with-disclosure LGPL-2.1+ MIT public-domain"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="dumb fluidsynth mad net +opengl +pcre portmidi sdl2-image +sdl2-mixer vorbis"
  18 REQUIRED_USE="sdl2-image? ( opengl )"
  19
  20 DEPEND="
  21         media-libs/libsdl2[opengl?,joystick,sound,video]
  22         dumb? ( media-libs/dumb:= )
  23         fluidsynth? ( media-sound/fluidsynth:= )
  24         mad? ( media-libs/libmad )
  25         net? ( media-libs/sdl2-net )
  26         pcre? ( dev-libs/libpcre:3 )
  27         portmidi? ( media-libs/portmidi )
  28         sdl2-image? ( media-libs/sdl2-image )
  29         sdl2-mixer? ( media-libs/sdl2-mixer[midi] )
  30         vorbis? ( media-libs/libvorbis )"
  31 RDEPEND="${DEPEND}"
  32
  33 S=${WORKDIR}/${MY_P}
  34 PATCHES=(
  35         "${FILESDIR}/${PN}-2.5.1.4-Remove-nonstandard-gamesdir-variable.patch"
  36 )
  37
  38 src_prepare() {
  39         xdg_src_prepare
  40         eautoreconf
  41 }
  42
  43 src_configure() {
  44         econf \
  45                 --disable-cpu-opt \
  46                 --disable-nonfree-graphics \
  47                 $(use_enable opengl gl) \
  48                 $(use_with dumb) \
  49                 $(use_with fluidsynth) \
  50                 $(use_with mad) \
  51                 $(use_with net) \
  52                 $(use_with pcre) \
  53                 $(use_with portmidi) \
  54                 $(use_with sdl2-image image) \
  55                 $(use_with sdl2-mixer mixer) \
  56                 $(use_with vorbis vorbisfile) \
  57                 --with-waddir="${EPREFIX}/usr/share/doom"
  58 }
  59
  60 src_install() {
  61         default
  62         doicon ICONS/${PN}.svg
  63         domenu ICONS/${PN}.desktop
  64 }