games-fps/freedoom-data/freedoom-data-0.12.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{5,6,7} )
   7
   8 inherit prefix python-any-r1 xdg
   9
  10 DESCRIPTION="Game resources for Freedoom: Phase 1+2"
  11 HOMEPAGE="https://freedoom.github.io"
  12 SRC_URI="https://github.com/freedoom/freedoom/archive/v${PV}.tar.gz -> freedoom-${PV}.tar.gz"
  13
  14 LICENSE="BSD"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~arm ~x86"
  17
  18 BDEPEND="
  19         $(python_gen_any_dep 'dev-python/pillow[${PYTHON_USEDEP}]')
  20         app-text/asciidoc
  21         games-util/deutex"
  22
  23 S="${WORKDIR}/freedoom-${PV}"
  24
  25 DOOMWADPATH=share/doom
  26
  27 python_check_deps() {
  28         has_version -b "dev-python/pillow[${PYTHON_USEDEP}]"
  29 }
  30
  31 src_prepare() {
  32         xdg_src_prepare
  33         eapply_user
  34
  35         hprefixify dist/freedoom
  36 }
  37
  38 src_compile() {
  39         emake wads/freedoom{1,2}.wad \
  40                 freedoom{1,2}.6 \
  41                 {NEWS,README}.html
  42 }
  43
  44 src_install() {
  45         emake install-freedoom \
  46                 prefix="${ED}/usr/" \
  47                 bindir="bin/" \
  48                 docdir="share/doc/${P}" \
  49                 mandir="share/man/" \
  50                 waddir="${DOOMWADPATH}/"
  51 }
  52
  53 pkg_postinst() {
  54         xdg_pkg_postinst
  55
  56         elog "Freedoom WAD files installed into ${EPREFIX}/usr/${DOOMWADPATH} directory."
  57 }