games-fps/blackshades/blackshades-20070723-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit eutils
   6
   7 DESCRIPTION="You control a psychic bodyguard, and try to protect the VIP"
   8 HOMEPAGE="http://www.wolfire.com/blackshades.html
   9         http://www.icculus.org/blackshades/"
  10 SRC_URI="http://filesingularity.timedoctor.org/Textures.tar.bz2
  11         mirror://gentoo/${P}.tar.bz2"
  12
  13 LICENSE="blackshades"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE=""
  17
  18 DEPEND="
  19         media-libs/freealut
  20         media-libs/libsdl
  21         media-libs/libvorbis
  22         media-libs/openal
  23         virtual/glu
  24         virtual/opengl"
  25 RDEPEND="${DEPEND}"
  26
  27 S=${WORKDIR}/${PN}
  28
  29 PATCHES=(
  30         "${FILESDIR}"/${PN}-datadir.patch
  31 )
  32
  33 src_prepare() {
  34         default
  35
  36         rm -rf Data/Textures || die
  37         rm -f ../Textures/{,Blood/}._* || die
  38         mv -f ../Textures Data || die "mv failed"
  39         sed -i \
  40                 -e "s/-O2 \(-Wall\) -g/${CXXFLAGS} \1/" \
  41                 -e "/^LINKER/s:$: ${LDFLAGS}:" \
  42                 Makefile \
  43                 || die "sed Makefile failed"
  44         sed -i "s:@DATADIR@:/usr/share/${PN}:" \
  45                 Source/Main.cpp \
  46                 || die "sed Main.cpp failed"
  47 }
  48
  49 src_compile() {
  50         emake bindir
  51         emake
  52 }
  53
  54 src_install() {
  55         newbin objs/blackshades ${PN}
  56         insinto /usr/share/${PN}
  57         doins -r Data
  58         dodoc IF_THIS_IS_A_README_YOU_HAVE_WON Readme TODO uDevGame_Readme
  59         make_desktop_entry ${PN} "Black Shades"
  60 }