games-emulation/lxdream/lxdream-0.9.1-r3.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit flag-o-matic
   6
   7 DESCRIPTION="An emulator for the Sega Dreamcast system"
   8 HOMEPAGE="http://www.lxdream.org/"
   9 SRC_URI="http://www.lxdream.org/count.php?file=${P}.tar.gz -> ${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 # lirc configure option is not recogniced
  15 IUSE="debug profile pulseaudio sdl" #lirc
  16
  17 RDEPEND="
  18         app-misc/lirc
  19
  20         media-libs/alsa-lib
  21         media-libs/libpng:0=
  22         pulseaudio? ( media-sound/pulseaudio )
  23         sdl? ( media-libs/libsdl[sound] )
  24         virtual/opengl
  25         x11-libs/gtk+:2
  26 "
  27 DEPEND="${RDEPEND}
  28         virtual/pkgconfig
  29         sys-devel/gettext
  30         virtual/os-headers
  31         !!gnustep-base/gnustep-gui" #377635
  32
  33 src_prepare() {
  34         default
  35
  36         eapply "${FILESDIR}/${PN}-0.9.1-glib-single-include.patch"
  37
  38         # Make .desktop file pass desktop-file-validate
  39         sed -i \
  40                 -e '/Encoding/d' \
  41                 -e '/FilePattern/d' \
  42                 -e '/Categories/s|$|;|' \
  43                 ${PN}.desktop || die
  44         # Do not override user-specified CFLAGS
  45         sed -i \
  46                 -e s/'CFLAGS=\"-g -fexceptions\"'/'CFLAGS=\"${CFLAGS} -g -fexceptions\"'/ \
  47                 -e '/CCOPT/d' \
  48                 -e '/OBJCOPT/d' \
  49                 configure || die
  50         append-libs -lX11 -lm
  51 }
  52
  53 src_configure() {
  54         # lirc configure option is not recognized
  55         # $(use_with lirc) \
  56         econf \
  57                 --datadir="/usr/share" \
  58                 $(use_enable debug trace) \
  59                 $(use_enable debug watch) \
  60                 $(use_enable profile profiled) \
  61                 $(use_with pulseaudio pulse) \
  62                 $(use_with sdl) \
  63                 --without-esd
  64 }