games-board/freedoko/freedoko-0.7.16.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit eutils flag-o-matic gnome2-utils
   6
   7 DESCRIPTION="FreeDoko is a Doppelkopf-game"
   8 HOMEPAGE="http://free-doko.sourceforge.net"
   9 SRC_URI="mirror://sourceforge/free-doko/FreeDoko_${PV}.src.zip
  10         backgrounds? ( mirror://sourceforge/free-doko/backgrounds.zip -> ${PN}-backgrounds.zip )
  11         kdecards? ( mirror://sourceforge/free-doko/kdecarddecks.zip )
  12         xskatcards? ( mirror://sourceforge/free-doko/xskat.zip )
  13         pysolcards? ( mirror://sourceforge/free-doko/pysol.zip )
  14         gnomecards? ( mirror://sourceforge/free-doko/gnome-games.zip )
  15         openclipartcards? ( mirror://sourceforge/free-doko/openclipart.zip )
  16         !xskatcards? (
  17                 !kdecards? (
  18                         !gnomecards? (
  19                                 !openclipartcards? (
  20                                         !pysolcards? (
  21                                                 mirror://sourceforge/free-doko/xskat.zip ) ) ) ) )"
  22
  23 LICENSE="GPL-2+"
  24 SLOT="0"
  25 KEYWORDS="~amd64 ~x86"
  26 IUSE="+xskatcards +gnomecards +kdecards +openclipartcards +pysolcards +backgrounds net"
  27
  28 RDEPEND="net? ( net-libs/gnet dev-libs/glib:2 )
  29         >=dev-cpp/gtkmm-2.4:2.4"
  30 DEPEND="${RDEPEND}
  31         app-arch/unzip
  32         virtual/pkgconfig"
  33
  34 S=${WORKDIR}/FreeDoko_${PV}
  35
  36 src_unpack() {
  37         local cards=0
  38
  39         unpack_cards() {
  40                 use $1 && { unpack $2 ; cards=$(( $cards + 1 )); };
  41         }
  42         unpack FreeDoko_${PV}.src.zip
  43         cp /dev/null "${S}"/src/Makefile.local || die
  44
  45         cd "${S}"/data/cardsets || die
  46
  47         unpack_cards xskatcards       xskat.zip
  48         unpack_cards kdecards         kdecarddecks.zip
  49         unpack_cards pysolcards       pysol.zip
  50         unpack_cards gnomecards       gnome-games.zip
  51         unpack_cards openclipartcards openclipart.zip
  52         [ $cards ] || unpack xskat.zip # fall back to xskat
  53
  54         if use backgrounds ; then
  55                 cd "${S}"/data/backgrounds || die
  56                 unpack ${PN}-backgrounds.zip
  57         fi
  58 }
  59
  60 PATCHES=(
  61         "${FILESDIR}"/${PN}-0.7.16-gentoo.patch
  62 )
  63
  64 src_prepare() {
  65         default
  66         export VARTEXFONTS="${T}/fonts" #652028
  67         append-cxxflags -std=c++14
  68 }
  69
  70 src_compile() {
  71         export CPPFLAGS="-DPUBLIC_DATA_DIRECTORY_VALUE='\"/usr/share/${PN}\"'"
  72         export CPPFLAGS+=" -DMANUAL_DIRECTORY_VALUE='\"/usr/share/doc/${PF}/html\"'"
  73         export OSTYPE=Linux
  74         export USE_NETWORK=$(use net && echo true || echo false)
  75         export USE_SOUND_ALUT=false # still marked experimental
  76         emake Version
  77         emake -C src FreeDoko
  78 }
  79
  80 src_install() {
  81         newbin src/FreeDoko freedoko
  82         insinto /usr/share/${PN}/
  83         doins -r data/{backgrounds,cardsets,iconsets,rules,sounds,translations,*png}
  84         find "${D}/usr/share/${PN}" -name Makefile -delete
  85         dodoc AUTHORS README ChangeLog
  86         newicon -s 32 src/FreeDoko.png ${PN}.png
  87         make_desktop_entry ${PN} FreeDoko
  88 }
  89
  90 pkg_preinst() {
  91         gnome2_icon_savelist
  92 }
  93
  94 pkg_postinst() {
  95         gnome2_icon_cache_update
  96 }
  97
  98 pkg_postrm() {
  99         gnome2_icon_cache_update
 100 }