games-board/awale/awale-1.5.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 # do not use autotools related stuff in stable ebuilds
   6 # unless you like random breakage: 469796, 469798, 424041
   7
   8 EAPI=5
   9
  10 inherit autotools eutils gnome2-utils games
  11
  12 DESCRIPTION="Free Awale - The game of all Africa"
  13 HOMEPAGE="http://www.nongnu.org/awale/"
  14 SRC_URI="mirror://nongnu/awale/${P}.tar.gz"
  15 SRC_URI="${SRC_URI} https://dev.gentoo.org/~hasufell/distfiles/${P}-no-autoreconf2.patch.xz" # STABLE ARCH
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS="amd64 x86"
  20 IUSE="tk"
  21
  22 RDEPEND="tk? ( dev-lang/tcl:0= dev-lang/tk:0= )"
  23
  24 src_prepare() {
  25         epatch "${FILESDIR}"/${P}-build.patch
  26
  27         mv src/xawale.tcl src/xawale.tcl.in || die
  28         mv configure.in configure.ac
  29         rm aclocal.m4
  30         eautoreconf
  31 }
  32
  33 src_configure() {
  34         egamesconf \
  35                 --mandir=/usr/share/man \
  36                 --with-iconsdir=/usr/share/icons/hicolor/48x48/apps \
  37                 --with-desktopdir=/usr/share/applications \
  38                 $(use_enable tk)
  39 }
  40
  41 src_install() {
  42         default
  43         prepgamesdirs
  44         use tk && fperms +x "${GAMES_DATADIR}"/${PN}/xawale.tcl
  45 }
  46
  47 pkg_preinst() {
  48         games_pkg_preinst
  49         use tk && gnome2_icon_savelist
  50 }
  51
  52 pkg_postinst() {
  53         games_pkg_postinst
  54         use tk && gnome2_icon_cache_update
  55 }
  56
  57 pkg_postrm() {
  58         use tk && gnome2_icon_cache_update
  59 }