games-arcade/savagewheels/savagewheels-1.6.1-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils
   7
   8 DESCRIPTION="2D car crashing game similar to the old classic Destruction Derby."
   9 HOMEPAGE="https://github.com/petarov/savagewheels"
  10
  11 GAMEDATA="${PN}-gamedata-1.4.0"
  12
  13 SRC_URI="
  14         https://github.com/petarov/savagewheels/archive/${PV}.tar.gz -> ${P}.tar.gz
  15         https://github.com/petarov/savagewheels/releases/download/v1.4/${PN}-gamedata.tar.gz -> ${GAMEDATA}.tar.gz
  16 "
  17
  18 LICENSE="MIT"
  19 SLOT="0"
  20 KEYWORDS="~amd64"
  21
  22 IUSE="fmod sound"
  23
  24 RDEPEND="
  25         media-libs/libsdl
  26         sound? (
  27                 !fmod? ( media-libs/sdl-mixer[mod,modplug] )
  28                 fmod? ( >=media-libs/fmod-4.38.00 )
  29         )"
  30
  31 DEPEND="${RDEPEND}"
  32
  33 REQUIRED_USE="fmod? ( sound )"
  34
  35 src_unpack() {
  36         unpack ${P}.tar.gz
  37
  38         cp "${FILESDIR}/${PN}.in" "${S}" || die
  39         mkdir "${WORKDIR}/${GAMEDATA}" ||
  40                 die "Failed to make directory: ${WORKDIR}/${GAMEDATA}"
  41         cd "${WORKDIR}/${GAMEDATA}" ||
  42                 die "Unable to change into directory: ${WORKDIR}/${GAMEDATA}"
  43         unpack "${GAMEDATA}.tar.gz"
  44 }
  45
  46 src_configure() {
  47         local mycmakeargs=(
  48                 -DCMAKE_INSTALL_DATADIR=share/${PN}
  49                 -DCMAKE_INSTALL_LIBEXECDIR=libexec/${PN}
  50                 $(usex sound $(usex fmod '-DSOUND=FMOD -DFMOD_PATH=/opt/fmodex/api' '-DSOUND=YES') '-DSOUND=NO')
  51         )
  52         cmake-utils_src_configure
  53 }
  54
  55 src_install() {
  56         cmake-utils_src_install
  57
  58         insinto /usr/share/${PN}
  59         doins -r "${WORKDIR}/${GAMEDATA}/."
  60 }