games-arcade/jvgs/jvgs-0.5-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils desktop
   7
   8 DESCRIPTION="An open-source platform game with a sketched and minimalistic look"
   9 HOMEPAGE="http://jvgs.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/jvgs/${P}-src.tar.gz"
  11
  12 LICENSE="WTFPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15
  16 RDEPEND="
  17         dev-lang/lua:0
  18         media-libs/libsdl[video]
  19         media-libs/sdl-mixer[vorbis]
  20         media-libs/freetype:2
  21         sys-libs/zlib:=
  22         virtual/opengl"
  23 DEPEND="${RDEPEND}
  24         dev-lang/swig"
  25
  26 S=${WORKDIR}/${P}-src
  27 PATCHES=( "${FILESDIR}"/${PN}-0.5-fix-build-system.patch )
  28
  29 src_install() {
  30         dobin src/${PN}
  31
  32         insinto /usr/share/${PN}
  33         doins -r main.lua resources
  34
  35         newicon resources/drawing.svg ${PN}.svg
  36         make_desktop_entry ${PN} ${PN}
  37
  38         einstalldocs
  39 }