games-arcade/diameter/diameter-0.4.0.3-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit autotools eutils python-single-r1
   9
  10 DESCRIPTION="Arcade game with elements of economy and adventure"
  11 HOMEPAGE="https://sourceforge.net/projects/gamediameter/"
  12 SRC_URI="mirror://sourceforge/gamediameter/${P}.tar.bz2"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE=""
  18 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  19
  20 RDEPEND="
  21         >=dev-games/guichan-0.8[opengl,sdl]
  22         media-libs/libpng:0=
  23         media-libs/libsdl[video]
  24         media-libs/sdl-image[gif,jpeg,png]
  25         media-libs/sdl-mixer[mod]
  26         virtual/opengl
  27         virtual/glu
  28         ${PYTHON_DEPS}"
  29 DEPEND="${RDEPEND}
  30         virtual/pkgconfig"
  31
  32 S=${WORKDIR}/gamediameter
  33
  34 src_prepare() {
  35         default
  36
  37         sed -i \
  38                 -e "s:gamediameter:diameter:" \
  39                 configure.in || die
  40         mv configure.in configure.ac || die
  41         sed -i \
  42                 -e '/for i in .*\/lib/s:".*:/usr/lib/ ; do:' \
  43                 -e "/AC_SUBST.*LDFLAGS/s/\".*\"/\$PYTHON_LIBS/" \
  44                 acinclude.m4 || die
  45         # bug #336812
  46         sed -i \
  47                 -e '/gui nebular3.gif/s/gui//' \
  48                 data/texture/Makefile.am || die
  49         eautoreconf
  50
  51         # needed, otherwise -lpython2.7 will not be found
  52         python_export PYTHON PYTHON_LIBS
  53 }
  54
  55 src_install() {
  56         default
  57
  58         newicon data/texture/gui/eng/main/logo.png ${PN}.png
  59         make_desktop_entry ${PN} ${PN^}
  60 }