games-action/violetland/violetland-0.5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake desktop xdg-utils
   7
   8 DESCRIPTION="Help a girl named Violet in the struggle with hordes of monsters"
   9 HOMEPAGE="https://violetland.github.io/"
  10 SRC_URI="https://github.com/ooxi/${PN}/releases/download/${PV}/${P}-source-with-dependencies.tar.gz"
  11
  12 LICENSE="GPL-3 CC-BY-SA-3.0"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15
  16 RDEPEND="
  17         dev-libs/boost:=[threads(+)]
  18         media-libs/libsdl[sound,video]
  19         media-libs/sdl-image[png]
  20         media-libs/sdl-mixer[vorbis]
  21         media-libs/sdl-ttf
  22         virtual/opengl
  23 "
  24
  25 DEPEND="${RDEPEND}"
  26
  27 BDEPEND="
  28         sys-devel/gettext
  29 "
  30
  31 src_prepare() {
  32         cmake_src_prepare
  33
  34         # Bizarrely fcitx is only bundled for a CMake module to find libintl
  35         # but let's make sure the rest remains unused.
  36         rm -r lib/fcitx/src || die
  37 }
  38
  39 src_configure() {
  40         local mycmakeargs=(
  41                 -DDATA_INSTALL_DIR="${EPREFIX}/usr/share/${PN}"
  42                 -DLOCALE_INSTALL_DIR=share/locale
  43         )
  44
  45         cmake_src_configure
  46 }
  47
  48 src_install() {
  49         cmake_src_install
  50         dodoc CHANGELOG.md CONTRIBUTORS.md
  51
  52         # Remove duplicate READMEs.
  53         rm -r "${ED}"/usr/share/${PN}/README* || die
  54
  55         newicon -s 64 icon-light.png ${PN}.png
  56         make_desktop_entry ${PN} VioletLand
  57 }
  58
  59 pkg_postinst() { xdg_icon_cache_update; }
  60 pkg_postrm() { xdg_icon_cache_update; }