games-action/swordandsworcery/swordandsworcery-1.02.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 # TODO: unbundle liblua-5.1 when available for multilib
   6
   7 EAPI=5
   8
   9 inherit eutils games
  10
  11 DESCRIPTION="An exploratory action adventure game with an emphasis on audiovisual style"
  12 HOMEPAGE="http://www.swordandsworcery.com/"
  13 SRC_URI="${PN}_${PV}.tar.gz"
  14
  15 LICENSE="CAPYBARA-EULA LGPL-3"
  16 SLOT="0"
  17 KEYWORDS="-* amd64 x86"
  18 IUSE="bundled-libs"
  19 RESTRICT="bindist fetch splitdebug"
  20
  21 MYGAMEDIR=${GAMES_PREFIX_OPT}/${PN}
  22 QA_PREBUILT="${MYGAMEDIR#/}/bin/*
  23         ${MYGAMEDIR#/}/lib/*"
  24
  25 # linked to pulseaudio
  26 RDEPEND="
  27         virtual/opengl
  28         amd64? (
  29                 >=dev-libs/openssl-1.0.1h-r2:0=[abi_x86_32(-)]
  30                 >=sys-libs/zlib-1.2.8-r1[abi_x86_32(-)]
  31                 >=virtual/glu-9.0-r1[abi_x86_32(-)]
  32                 >=virtual/opengl-7.0-r1[abi_x86_32(-)]
  33                 >=media-libs/alsa-lib-1.0.27.2[abi_x86_32(-)]
  34                 >=media-libs/flac-1.2.1-r5[abi_x86_32(-)]
  35                 >=media-libs/libogg-1.3.0[abi_x86_32(-)]
  36                 >=media-libs/libsndfile-1.0.25[abi_x86_32(-)]
  37                 >=media-libs/libvorbis-1.3.3-r1[abi_x86_32(-)]
  38                 >=media-sound/pulseaudio-2.1-r1[abi_x86_32(-)]
  39                 >=x11-libs/libICE-1.0.8-r1[abi_x86_32(-)]
  40                 >=x11-libs/libSM-1.2.1-r1[abi_x86_32(-)]
  41                 >=x11-libs/libX11-1.6.2[abi_x86_32(-)]
  42                 >=x11-libs/libXau-1.0.7-r1[abi_x86_32(-)]
  43                 >=x11-libs/libxcb-1.9.1[abi_x86_32(-)]
  44                 >=x11-libs/libXdmcp-1.1.1-r1[abi_x86_32(-)]
  45                 >=x11-libs/libXext-1.3.2[abi_x86_32(-)]
  46                 >=x11-libs/libXi-1.7.2[abi_x86_32(-)]
  47                 >=x11-libs/libXtst-1.2.1-r1[abi_x86_32(-)]
  48                 !bundled-libs? (
  49                         >=net-misc/curl-7.36.0[abi_x86_32(-)]
  50                         >=media-libs/libsdl-1.2.15-r4[X,sound,video,opengl,joystick,abi_x86_32(-)]
  51                 )
  52         )
  53         x86? (
  54                 dev-libs/openssl:0=
  55                 media-libs/alsa-lib
  56                 media-libs/flac
  57                 media-libs/libogg
  58                 media-libs/libsndfile
  59                 media-libs/libvorbis
  60                 media-sound/pulseaudio
  61                 sys-libs/zlib
  62                 virtual/glu
  63                 x11-libs/libICE
  64                 x11-libs/libSM
  65                 x11-libs/libX11
  66                 x11-libs/libXau
  67                 x11-libs/libxcb
  68                 x11-libs/libXdmcp
  69                 x11-libs/libXext
  70                 x11-libs/libXi
  71                 x11-libs/libXtst
  72                 !bundled-libs? (
  73                         net-misc/curl
  74                         media-libs/libsdl[X,sound,video,opengl,joystick]
  75                 )
  76         )"
  77
  78 S=${WORKDIR}
  79
  80 pkg_nofetch() {
  81         einfo "Please buy & download ${SRC_URI} from:"
  82         einfo "  ${HOMEPAGE}"
  83         einfo "and move it to ${DISTDIR}"
  84 }
  85
  86 src_prepare() {
  87         if ! use bundled-libs ; then
  88                 einfo "removing bundled libs..."
  89                 rm -v lib/libcurl.so* lib/libSDL-1.2.so* \
  90                         lib/libstdc++.so* || die
  91         fi
  92
  93         sed \
  94                 -e "s#@GAMEDIR@#${MYGAMEDIR}#" \
  95                 "${FILESDIR}"/${PN}-wrapper > "${T}"/${PN} || die
  96 }
  97
  98 src_install() {
  99         insinto "${MYGAMEDIR}"
 100         doins -r bin lib res
 101
 102         dogamesbin "${T}"/${PN}
 103         make_desktop_entry ${PN}
 104
 105         dohtml README.html
 106
 107         fperms +x "${MYGAMEDIR}"/bin/${PN}
 108         prepgamesdirs
 109 }