games-action/lugaru/lugaru-20151204-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake desktop
   7
   8 DESCRIPTION="3D arcade with unique fighting system and anthropomorphic characters"
   9 HOMEPAGE="https://bitbucket.org/osslugaru/lugaru/wiki/Home"
  10 SRC_URI="mirror://gentoo/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2+ free-noncomm CC-BY-SA-3.0"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE=""
  16
  17 RDEPEND="
  18         media-libs/libpng:0=
  19         media-libs/libsdl:=[opengl,video]
  20         media-libs/libvorbis:=
  21         media-libs/openal:=
  22         sys-libs/zlib:=
  23         virtual/glu
  24         virtual/jpeg:0
  25         virtual/opengl"
  26 DEPEND="${RDEPEND}
  27         virtual/pkgconfig"
  28
  29 PATCHES=(
  30         "${FILESDIR}"/${P}-dir.patch
  31         "${FILESDIR}"/${P}-jpeg-9c.patch
  32 )
  33
  34 src_prepare() {
  35         cmake_src_prepare
  36
  37         sed -i \
  38                 -e "s:@GENTOO_DIR@:/usr/share/${PN}:" \
  39                 Source/OpenGL_Windows.cpp || die
  40 }
  41
  42 src_configure() {
  43         local mycmakeargs=(
  44                 -DCMAKE_VERBOSE_MAKEFILE=TRUE
  45                 -DLUGARU_FORCE_INTERNAL_OPENGL=False
  46         )
  47         cmake_src_configure
  48 }
  49
  50 src_install() {
  51         dobin "${BUILD_DIR}"/lugaru
  52         insinto /usr/share/${PN}
  53         doins -r Data
  54         newicon Source/win-res/Lugaru.png ${PN}.png
  55         make_desktop_entry ${PN} Lugaru ${PN}
  56 }