games-action/koth/koth-0.8.0-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit eutils flag-o-matic
   6
   7 DESCRIPTION="Multiplayer, networked game of little tanks with really big weapons"
   8 HOMEPAGE="http://www.nongnu.org/koth/"
   9 SRC_URI="https://savannah.nongnu.org/download/${PN}/default.pkg/${PV}/${P}.tar.bz2"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~alpha ~amd64 ~x86 ~x86-fbsd"
  14 IUSE=""
  15
  16 DEPEND="media-libs/libggi"
  17 RDEPEND="${DEPEND}"
  18
  19 PATCHES=(
  20         "${FILESDIR}"/${PF}-gcc-3.4.patch
  21 )
  22
  23 src_prepare() {
  24         default
  25         sed -i 's:-g -O2::' configure || die
  26         sed -i 's:(uint16):(uint16_t):' src/gfx.c src/gfx.h || die
  27         append-cflags -std=gnu89 # build with gcc5 (bug #570730)
  28 }
  29
  30 src_install() {
  31         DOCS="AUTHORS ChangeLog NEWS README doc/*.txt" \
  32                 default
  33         dodir /etc/koth
  34         insinto /etc/koth
  35         doins src/koth.cfg
  36 }