games-action/dxx-rebirth/dxx-rebirth-0.59.100.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils scons-utils toolchain-funcs xdg
   7
   8 MY_P="${PN}_v${PV}-src"
   9 DESCRIPTION="Descent Rebirth - enhanced Descent 1 & 2 engine"
  10 HOMEPAGE="https://www.dxx-rebirth.com/"
  11 SRC_URI="https://www.dxx-rebirth.com/download/dxx/${MY_P}.tar.gz
  12         opl3-musicpack? (
  13                 descent1? ( https://www.dxx-rebirth.com/download/dxx/res/d1xr-opl3-music.dxa )
  14                 descent2? ( https://www.dxx-rebirth.com/download/dxx/res/d2xr-opl3-music.dxa ) )
  15         sc55-musicpack? (
  16                 descent1? ( https://www.dxx-rebirth.com/download/dxx/res/d1xr-sc55-music.dxa )
  17                 descent2? ( https://www.dxx-rebirth.com/download/dxx/res/d2xr-sc55-music.dxa ) )
  18         l10n_de? (
  19                 descent1? ( https://www.dxx-rebirth.com/download/dxx/res/d1xr-briefings-ger.dxa )
  20                 descent2? ( https://www.dxx-rebirth.com/download/dxx/res/d2xr-briefings-ger.dxa ) )
  21         textures? (
  22                 descent1? ( https://www.dxx-rebirth.com/download/dxx/res/d1xr-hires.dxa ) )"
  23
  24 LICENSE="DXX-Rebirth GPL-3 public-domain"
  25 SLOT="0"
  26 KEYWORDS="~amd64 ~x86"
  27 IUSE="+data debug +descent1 +descent2 ipv6 l10n_de +music +opengl opl3-musicpack sc55-musicpack +textures"
  28
  29 REQUIRED_USE="|| ( descent1 descent2 )
  30         ?? ( opl3-musicpack sc55-musicpack )
  31         opl3-musicpack? ( music )
  32         sc55-musicpack? ( music )"
  33
  34 DEPEND="dev-games/physfs:0=[hog,mvl,zip]
  35         media-libs/libsdl:0=[joystick,opengl?,sound,video]
  36         music? ( media-libs/sdl-mixer:0= )
  37         opengl? (
  38                 virtual/opengl
  39                 virtual/glu )"
  40
  41 RDEPEND="${DEPEND}
  42         data? (
  43                 descent1? ( || ( games-action/descent1-data games-action/descent1-demodata ) )
  44                 descent2? ( || ( games-action/descent2-data games-action/descent2-demodata ) ) )
  45         music? (
  46                 !opl3-musicpack? ( !sc55-musicpack? ( media-libs/sdl-mixer:0=[midi] ) )
  47                 opl3-musicpack? ( media-libs/sdl-mixer:0=[vorbis] )
  48                 sc55-musicpack? ( media-libs/sdl-mixer:0=[vorbis] ) )
  49         !games-action/d1x-rebirth
  50         !games-action/d2x-rebirth"
  51
  52 S="${WORKDIR}/${MY_P}"
  53
  54 PATCHES=(
  55         "${FILESDIR}"/${P}-flags.patch # Remove hardcoded optimisation flags.
  56         "${FILESDIR}"/${P}-sharepath.patch # Change share path to use old d1x/d2x locations.
  57         "${FILESDIR}"/${P}-physfs-3-no-deprecation.patch # bug #653014
  58 )
  59
  60 src_compile() {
  61         tc-export CXX
  62         escons \
  63                 prefix="${EPREFIX}"/usr \
  64                 d1x=$(usex descent1 1 0) \
  65                 d2x=$(usex descent2 1 0) \
  66                 debug=$(usex debug 1 0) \
  67                 ipv6=$(usex ipv6 1 0) \
  68                 opengl=$(usex opengl 1 0) \
  69                 sdlmixer=$(usex music 1 0) \
  70                 verbosebuild=1
  71 }
  72
  73 src_install() {
  74         local DV PROGRAM
  75
  76         for DV in 1 2; do
  77                 use descent${DV} || continue
  78                 PROGRAM=d${DV}x-rebirth
  79
  80                 docinto ${PROGRAM}
  81                 edos2unix ${PROGRAM}/*.txt
  82                 dodoc ${PROGRAM}/*.txt
  83
  84                 insinto /usr/share/games/d${DV}x
  85                 use opl3-musicpack && doins "${DISTDIR}"/d${DV}xr-opl3-music.dxa
  86                 use sc55-musicpack && doins "${DISTDIR}"/d${DV}xr-sc55-music.dxa
  87                 use l10n_de && doins "${DISTDIR}"/d${DV}xr-briefings-ger.dxa
  88
  89                 dobin ${PROGRAM}/${PROGRAM}
  90                 make_desktop_entry ${PROGRAM} "Descent ${DV} Rebirth" ${PROGRAM}
  91                 doicon ${PROGRAM}/${PROGRAM}.xpm
  92         done
  93
  94         if use textures && use descent1; then
  95                 insinto /usr/share/games/d1x
  96                 doins "${DISTDIR}"/d1xr-hires.dxa
  97         fi
  98 }
  99
 100 pkg_postinst() {
 101         xdg_pkg_postinst
 102
 103         if ! use data; then
 104                 elog "To play the game enable USE=\"data\" or manually "
 105                 elog "copy the files to ${EPREFIX}/usr/share/games/{d1x,d2x}."
 106                 elog "See each game's INSTALL.txt for details."
 107         fi
 108 }