dev-vcs/rapidsvn/rapidsvn-0.12.1-r3.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 PYTHON_COMPAT=( python2_7 )
   8
   9 WX_GTK_VER=3.0
  10
  11 inherit autotools eutils fdo-mime flag-o-matic python-single-r1 versionator wxwidgets
  12
  13 MY_PV=$(get_version_component_range 1-2)
  14 MY_REL="1"
  15
  16 DESCRIPTION="Cross-platform GUI front-end for the Subversion revision system"
  17 HOMEPAGE="http://rapidsvn.tigris.org/"
  18 SRC_URI="
  19         http://www.rapidsvn.org/download/release/${PV}/${P}.tar.gz
  20         doc? ( https://dev.gentoo.org/~jlec/distfiles/svncpp.dox.xz )"
  21
  22 LICENSE="GPL-2 LGPL-2.1 FDL-1.2"
  23 SLOT="0"
  24 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
  25 IUSE="doc static-libs"
  26
  27 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  28
  29 COMMON_DEP="
  30         ${PYTHON_DEPS}
  31         dev-libs/apr
  32         dev-libs/apr-util
  33         dev-vcs/subversion
  34         x11-libs/wxGTK:${WX_GTK_VER}[X]"
  35 DEPEND="${COMMON_DEP}
  36         doc? (
  37                 dev-libs/libxslt
  38                 app-text/docbook-sgml-utils
  39                 app-doc/doxygen
  40                 app-text/docbook-xsl-stylesheets
  41                 media-gfx/graphviz
  42         )"
  43 RDEPEND="${COMMON_DEP}"
  44
  45 PATCHES=(
  46         "${FILESDIR}/${P}-svncpp_link.patch"
  47         "${FILESDIR}/${P}-locale.patch"
  48         "${FILESDIR}/${P}-wx3.0.patch"
  49         "${FILESDIR}/${P}-subversion1.9-private-api.patch"
  50 )
  51
  52 DOCS=( HACKING.txt TRANSLATIONS )
  53
  54 src_prepare() {
  55         need-wxwidgets unicode
  56         if use doc; then
  57                 mv "${WORKDIR}"/svncpp.dox doc/svncpp/ || die
  58         fi
  59         strip-linguas $(grep ^RAPIDSVN_LANGUAGES src/locale/Makefile.am | sed 's:RAPIDSVN_LANGUAGES=::g')
  60         sed \
  61                 -e "/^RAPIDSVN_LANGUAGES/s:=.*:=${LINGUAS}:g" \
  62                 -i src/locale/Makefile.am || die
  63
  64         mv configure.in configure.ac || die
  65
  66         default
  67         eautoreconf
  68 }
  69
  70 src_configure() {
  71         append-cppflags $( apr-1-config --cppflags )
  72         econf \
  73                 $(use_enable static-libs static) \
  74                 $(use_with doc manpage) \
  75                 $(use_with doc xsltproc) \
  76                 $(use_with doc doxygen) \
  77                 $(use_with doc dot) \
  78                 --with-wx-config="${WX_CONFIG}" \
  79                 --with-svn-lib="${EPREFIX}/usr/$(get_libdir)" \
  80                 --with-svn-include="${EPREFIX}/usr/include" \
  81                 --with-apr-config="${EPREFIX}/usr/bin/apr-1-config" \
  82                 --with-apu-config="${EPREFIX}/usr/bin/apu-1-config"
  83 }
  84
  85 src_compile() {
  86         default
  87         use doc && emake -C doc/manpage manpage
  88 }
  89
  90 src_install() {
  91         default
  92
  93         doicon src/res/rapidsvn.ico src/res/bitmaps/${PN}*.png
  94         make_desktop_entry rapidsvn "RapidSVN ${PV}" \
  95                 "${EPREFIX}/usr/share/pixmaps/rapidsvn_32x32.png" \
  96                 "RevisionControl;Development"
  97
  98         if use doc ; then
  99                 doman doc/manpage/${PN}.1
 100                 dodoc doc/svncpp/html/*
 101         fi
 102
 103         prune_libtool_files
 104 }
 105
 106 src_test() {
 107         pushd src/tests/svncpp > /dev/null || die
 108         default
 109         ./svncpptest | grep OK || die
 110 }
 111
 112 pkg_postinst() {
 113         fdo-mime_desktop_database_update
 114 }
 115
 116 pkg_postrm() {
 117         fdo-mime_desktop_database_update
 118 }