dev-vcs/rapidsvn/rapidsvn-0.12.1-r2.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 PYTHON_COMPAT=( python2_7 )
   8
   9 WX_GTK_VER=3.0
  10
  11 AUTOTOOLS_AUTORECONF=true
  12
  13 inherit autotools-utils fdo-mime flag-o-matic multilib python-single-r1 versionator wxwidgets
  14
  15 MY_PV=$(get_version_component_range 1-2)
  16 MY_REL="1"
  17
  18 DESCRIPTION="Cross-platform GUI front-end for the Subversion revision system"
  19 HOMEPAGE="http://rapidsvn.tigris.org/"
  20 SRC_URI="
  21         http://www.rapidsvn.org/download/release/${PV}/${P}.tar.gz
  22         doc? ( https://dev.gentoo.org/~jlec/distfiles/svncpp.dox.xz )"
  23
  24 LICENSE="GPL-2 LGPL-2.1 FDL-1.2"
  25 SLOT="0"
  26 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
  27 IUSE="doc static-libs"
  28
  29 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  30
  31 COMMON_DEP="
  32         ${PYTHON_DEPS}
  33         dev-libs/apr
  34         dev-libs/apr-util
  35         dev-vcs/subversion
  36         x11-libs/wxGTK:${WX_GTK_VER}[X]"
  37 DEPEND="${COMMON_DEP}
  38         doc? (
  39                 dev-libs/libxslt
  40                 app-text/docbook-sgml-utils
  41                 app-doc/doxygen
  42                 app-text/docbook-xsl-stylesheets
  43                 media-gfx/graphviz
  44 )"
  45 RDEPEND="${COMMON_DEP}"
  46
  47 PATCHES=(
  48         "${FILESDIR}/${P}-svncpp_link.patch"
  49         "${FILESDIR}/${P}-locale.patch"
  50         "${FILESDIR}/${P}-wx3.0.patch" )
  51
  52 AUTOTOOLS_IN_SOURCE_BUILD=1
  53
  54 DOCS=( HACKING.txt TRANSLATIONS )
  55
  56 src_prepare() {
  57         need-wxwidgets unicode
  58         if use doc; then
  59                 mv "${WORKDIR}"/svncpp.dox doc/svncpp/ || die
  60         fi
  61         strip-linguas $(grep ^RAPIDSVN_LANGUAGES src/locale/Makefile.am | sed 's:RAPIDSVN_LANGUAGES=::g')
  62         sed \
  63                 -e "/^RAPIDSVN_LANGUAGES/s:=.*:=${LINGUAS}:g" \
  64                 -i src/locale/Makefile.am || die
  65
  66         mv configure.in configure.ac || die
  67
  68         autotools-utils_src_prepare
  69 }
  70
  71 src_configure() {
  72         local myeconfargs=( --with-wx-config=${WX_CONFIG} )
  73
  74         if use doc; then
  75                 myeconfargs+=( --with-manpage=yes )
  76         else
  77                 myeconfargs+=(
  78                                 --without-xsltproc
  79                                 --with-manpage=no
  80                                 --without-doxygen
  81                                 --without-dot )
  82         fi
  83
  84         append-cppflags $( apr-1-config --cppflags )
  85
  86         myeconfargs+=(
  87                 --with-svn-lib="${EPREFIX}"/usr/$(get_libdir)
  88                 --with-svn-include="${EPREFIX}"/usr/include
  89                 --with-apr-config="${EPREFIX}/usr/bin/apr-1-config"
  90                 --with-apu-config="${EPREFIX}/usr/bin/apu-1-config"
  91                 )
  92         autotools-utils_src_configure
  93 }
  94
  95 src_compile() {
  96         autotools-utils_src_compile
  97         use doc && autotools-utils_src_compile -C doc/manpage manpage
  98 }
  99
 100 src_install() {
 101         autotools-utils_src_install
 102
 103         doicon src/res/rapidsvn.ico src/res/bitmaps/${PN}*.png
 104         make_desktop_entry rapidsvn "RapidSVN ${PV}" \
 105                 "${EPREFIX}/usr/share/pixmaps/rapidsvn_32x32.png" \
 106                 "RevisionControl;Development"
 107
 108         if use doc ; then
 109                 doman doc/manpage/${PN}.1
 110                 dohtml "${S}"/doc/svncpp/html/*
 111         fi
 112 }
 113
 114 src_test() {
 115         pushd "${BUILD_DIR}"/src/tests/svncpp > /dev/null || die
 116         emake
 117         ./svncpptest | grep OK || die
 118 }
 119
 120 pkg_postinst() {
 121         fdo-mime_desktop_database_update
 122 }
 123
 124 pkg_postrm() {
 125         fdo-mime_desktop_database_update
 126 }