dev-vcs/kdesvn/kdesvn-1.7.0.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 KDE_HANDBOOK="optional"
   8 KDE_LINGUAS="cs de el es fr it ja lt pt_BR ro ru"
   9 KDE_LINGUAS_LIVE_OVERRIDE="true"
  10 inherit flag-o-matic kde4-base
  11
  12 DESCRIPTION="A frontend to the subversion vcs"
  13 HOMEPAGE="http://kdesvn.alwins-world.de/"
  14 if [[ ${PV} != 9999* ]]; then
  15         SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
  16 fi
  17
  18 LICENSE="GPL-2"
  19 KEYWORDS="amd64 ~x86"
  20 SLOT="4"
  21 IUSE="debug"
  22
  23 DEPEND="
  24         dev-libs/apr:1
  25         dev-libs/apr-util:1
  26         dev-qt/qtsql:4[sqlite]
  27         >=dev-vcs/subversion-1.7
  28         sys-devel/gettext
  29 "
  30 RDEPEND="${DEPEND}
  31         !kde-apps/kdesdk-kioslaves:4[subversion(+)]
  32 "
  33
  34 # bug #583286: needs network access
  35 RESTRICT="test"
  36
  37 src_configure() {
  38         append-cppflags -DQT_THREAD_SUPPORT
  39
  40         [[ ${PV} = 9999* ]] && local mycmakeargs=(-DDAILY_BUILD=ON)
  41
  42         kde4-base_src_configure
  43 }