dev-vcs/gitolite/gitolite-3.6.1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit perl-module user versionator
   8
   9 DESCRIPTION="Highly flexible server for git directory version tracker"
  10 HOMEPAGE="https://github.com/sitaramc/gitolite"
  11 SRC_URI="https://github.com/sitaramc/gitolite/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~arm ~x86"
  16 IUSE="tools vim-syntax"
  17
  18 DEPEND="dev-lang/perl
  19         virtual/perl-File-Path
  20         virtual/perl-File-Temp
  21         >=dev-vcs/git-1.6.6"
  22 RDEPEND="${DEPEND}
  23         !dev-vcs/gitolite-gentoo
  24         vim-syntax? ( app-vim/gitolite-syntax )
  25         dev-perl/JSON"
  26
  27 pkg_setup() {
  28         enewgroup git
  29         enewuser git -1 /bin/sh /var/lib/gitolite git
  30 }
  31
  32 src_prepare() {
  33         echo $PF > src/VERSION
  34 }
  35
  36 src_install() {
  37         local uexec=/usr/libexec/${PN}
  38
  39         rm -rf src/lib/Gitolite/Test{,.pm}
  40         insinto $VENDOR_LIB
  41         doins -r src/lib/Gitolite
  42
  43         dodoc README.txt CHANGELOG
  44
  45         insopts -m0755
  46         insinto $uexec
  47         doins -r src/{commands,syntactic-sugar,triggers,VREF}/
  48
  49         insopts -m0644
  50         doins src/VERSION
  51
  52         exeinto $uexec
  53         doexe src/gitolite{,-shell}
  54
  55         dodir /usr/bin
  56         for bin in gitolite{,-shell}; do
  57                 dosym /usr/libexec/${PN}/${bin} /usr/bin/${bin}
  58         done
  59
  60         if use tools; then
  61                 dobin check-g2-compat convert-gitosis-conf
  62         fi
  63
  64         keepdir /var/lib/gitolite
  65         fowners git:git /var/lib/gitolite
  66         fperms 750 /var/lib/gitolite
  67
  68         fperms 0644 ${uexec}/VREF/MERGE-CHECK # It's meant as example only
  69 }
  70
  71 pkg_postinst() {
  72         if [[ "$(get_major_version $REPLACING_VERSIONS)" == "2" ]]; then
  73                 ewarn
  74                 elog "***NOTE*** This is a major upgrade and will likely break your existing gitolite-2.x setup!"
  75                 elog "Please read http://gitolite.com/gitolite/migr.html first!"
  76         fi
  77
  78         # bug 352291
  79         ewarn
  80         elog "Please make sure that your 'git' user has the correct homedir (/var/lib/gitolite)."
  81         elog "Especially if you're migrating from gitosis."
  82         ewarn
  83 }