dev-vcs/cvs-fast-export/cvs-fast-export-1.55.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="fast-export history from a CVS repository or RCS collection"
   9 HOMEPAGE="http://www.catb.org/~esr/cvs-fast-export/"
  10 SRC_URI="http://www.catb.org/~esr/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE=""
  16
  17 RDEPEND=""
  18 DEPEND="${RDEPEND}
  19         app-text/asciidoc"
  20
  21 RESTRICT=test # upstream does not ship some tests in tarball
  22
  23 src_prepare() {
  24         default
  25
  26         tc-export CC
  27         export prefix="${EPREFIX}"/usr
  28
  29         # respect CC, CFLAGS and LDFLAGS
  30         sed \
  31                 -e 's/cc /$(CC) $(LDFLAGS) /' \
  32                 -e 's/^CFLAGS += -O/#&/' \
  33                 -e 's/CFLAGS=/CFLAGS+=/' \
  34                 -i Makefile || die
  35 }
  36
  37 src_compile() {
  38         # '.adoc.html' rules can't be executed in parallel
  39         # as they reuse the same 'docbook-xsl.css' file name.
  40         emake -j1 html
  41         # Allow full parallelism for the rest
  42         emake
  43 }
  44
  45 src_install() {
  46         default
  47         dodoc README.adoc
  48 }