dev-util/xdelta/xdelta-3.1.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 )
   6
   7 WANT_AUTOMAKE=1.14
   8 inherit autotools python-any-r1
   9
  10 MY_P=xdelta3-${PV}
  11
  12 DESCRIPTION="Computes changes between binary or text files and creates deltas"
  13 HOMEPAGE="http://xdelta.org/"
  14 SRC_URI="https://github.com/jmacd/xdelta-gpl/releases/download/v${PV}/${MY_P}.tar.gz"
  15
  16 LICENSE="GPL-2"
  17 SLOT="3"
  18 KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
  19 IUSE="examples test"
  20 RESTRICT="!test? ( test )"
  21
  22 RDEPEND="app-arch/xz-utils"
  23 DEPEND="${RDEPEND}
  24         test? ( ${PYTHON_DEPS} )"
  25
  26 S=${WORKDIR}/${MY_P}
  27
  28 pkg_setup() {
  29         use test && python-any-r1_pkg_setup
  30 }
  31
  32 src_prepare() {
  33         eapply_user
  34
  35         # huh
  36         sed -i -e '/python/s:2.6:2:' testing/xdelta3-regtest.py || die
  37         sed -i -e '/python/s:2.7:2:' testing/xdelta3-test.py || die
  38
  39         # only build tests when required
  40         sed -i -e '/xdelta3regtest/s:noinst_P:check_P:' Makefile.am || die
  41         eautomake
  42 }
  43
  44 src_test() {
  45         default
  46         ./xdelta3regtest || die
  47 }
  48
  49 src_install() {
  50         emake DESTDIR="${D}" install
  51         dodoc draft-korn-vcdiff.txt README.md
  52         use examples && dodoc -r examples
  53 }