dev-util/vulkan-tools/vulkan-tools-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_{5,6,7} )
   6
   7 if [[ "${PV}" == "9999" ]]; then
   8         EGIT_REPO_URI="https://github.com/KhronosGroup/Vulkan-Tools.git"
   9         EGIT_SUBMODULES=()
  10         inherit git-r3
  11 else
  12         EGIT_COMMIT="9bbdd552f0fd62741aa1f1e02ab3eafc45cf3c1e"
  13         KEYWORDS="~amd64"
  14         SRC_URI="https://github.com/KhronosGroup/Vulkan-Tools/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
  15         S="${WORKDIR}/Vulkan-Tools-${EGIT_COMMIT}"
  16 fi
  17
  18 inherit python-any-r1 cmake-multilib
  19
  20 DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
  21 HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
  22
  23 LICENSE="Apache-2.0"
  24 SLOT="0"
  25 IUSE="+cube +vulkaninfo +X wayland"
  26 COMMON_DEPEND="media-libs/vulkan-loader:=[${MULTILIB_USEDEP},wayland?,X?]
  27         wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
  28         X? (
  29                 x11-libs/libX11:=[${MULTILIB_USEDEP}]
  30                 x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
  31         )"
  32
  33 BDEPEND="${PYTHON_DEPS}
  34         cube? ( dev-util/glslang:=[${MULTILIB_USEDEP}] )"
  35 DEPEND="${COMMON_DEPEND}"
  36 RDEPEND="${COMMON_DEPEND}"
  37
  38 # Vulkaninfo does not support wayland
  39 REQUIRED_USE="|| ( X wayland )
  40                         vulkaninfo? ( X )"
  41
  42 pkg_setup() {
  43         MULTILIB_CHOST_TOOLS=()
  44
  45         if use vulkaninfo; then
  46                 MULTILIB_CHOST_TOOLS+=( /usr/bin/vulkaninfo )
  47         fi
  48
  49         if use cube; then
  50                 MULTILIB_CHOST_TOOLS+=(
  51                         /usr/bin/vkcube
  52                         /usr/bin/vkcubepp
  53                 )
  54         fi
  55
  56         python-any-r1_pkg_setup
  57 }
  58
  59 multilib_src_configure() {
  60         local mycmakeargs=(
  61                 -DCMAKE_SKIP_RPATH=True
  62                 -DBUILD_CUBE=$(usex cube)
  63                 -DBUILD_VULKANINFO=$(usex vulkaninfo)
  64                 -DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
  65                 -DBUILD_WSI_XCB_SUPPORT=$(usex X)
  66                 -DBUILD_WSI_XLIB_SUPPORT=$(usex X)
  67                 -DGLSLANG_INSTALL_DIR="/usr"
  68                 -DVULKAN_HEADERS_INSTALL_DIR="/usr"
  69         )
  70
  71         # Upstream only supports one window system at a time
  72         # If X is set at all, even if wayland is set, use X
  73         #
  74         # If -cube and/or -vulkaninfo is set, the flags we set
  75         # are ignored, so we don't need to consider that
  76         if use X; then
  77                 mycmakeargs+=(
  78                         -DCUBE_WSI_SELECTION="XCB"
  79                 )
  80         fi
  81
  82         if ! use X && use wayland; then
  83                 mycmakeargs+=(
  84                         -DCUBE_WSI_SELECTION="WAYLAND"
  85                 )
  86         fi
  87
  88         cmake-utils_src_configure
  89 }
  90
  91 multilib_src_install() {
  92         cmake-utils_src_install
  93 }