dev-util/ticpp/ticpp-0_p20120423.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 DESCRIPTION="A completely new interface to TinyXML that uses MANY of the C++ strengths"
   8 HOMEPAGE="https://github.com/rjpcomputing/ticpp"
   9 SRC_URI="https://dev.gentoo.org/~ago/distfiles/${P}.tar.bz2"
  10
  11 LICENSE="MIT"
  12 KEYWORDS="amd64 ~ppc x86"
  13 SLOT="0"
  14 IUSE="debug doc"
  15
  16 DEPEND="dev-util/premake:4
  17         doc? ( app-doc/doxygen )"
  18 RDEPEND=""
  19
  20 src_prepare() {
  21         premake4 gmake || die
  22
  23         sed -i "s:\$(ARCH)::g" TiCPP.make || die
  24 }
  25
  26 src_compile() {
  27         local myconf
  28         use !debug && myconf="config=release"
  29         emake ${myconf}
  30
  31         if use doc ; then
  32                 sed -i -e '/GENERATE_HTMLHELP/s:YES:NO:' dox || die
  33                 doxygen dox || die
  34         fi
  35 }
  36
  37 src_install () {
  38         insinto /usr/include/ticpp
  39         doins *.h
  40
  41         if use debug ; then
  42                 dolib lib/libticppd.a
  43         else
  44                 dolib lib/libticpp.a
  45         fi
  46
  47         dodoc {changes,readme,tutorial_gettingStarted,tutorial_ticpp}.txt
  48
  49         use doc && dohtml -r docs/*
  50 }