dev-util/sysdig/sysdig-0.26.6.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit bash-completion-r1 cmake
   7
   8 DESCRIPTION="A system exploration and troubleshooting tool"
   9 HOMEPAGE="https://sysdig.com/"
  10 SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="Apache-2.0"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="libressl +modules test"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="
  19         app-misc/jq:0=
  20         dev-cpp/tbb:0=
  21         dev-lang/luajit:2=
  22         >=dev-libs/jsoncpp-0.6_pre:0=
  23         dev-libs/libb64:0=
  24         dev-libs/protobuf:0=
  25         net-dns/c-ares:0=
  26         net-libs/grpc:0=
  27         sys-libs/ncurses:0=
  28         sys-libs/zlib:0=
  29         libressl? ( dev-libs/libressl:0= )
  30         !libressl? ( dev-libs/openssl:0= )
  31         net-misc/curl:0="
  32 DEPEND="${RDEPEND}
  33         virtual/os-headers
  34         test? ( dev-cpp/gtest )"
  35 PDEPEND="
  36         modules? ( >=dev-util/sysdig-kmod-${PV} )"
  37
  38 src_prepare() {
  39         sed -i -e 's:-ggdb::' CMakeLists.txt || die
  40
  41         cmake_src_prepare
  42 }
  43
  44 src_configure() {
  45         local mycmakeargs=(
  46                 -DCREATE_TEST_TARGETS=$(usex test)
  47
  48                 # done in dev-util/sysdig-kmod
  49                 -DBUILD_DRIVER=OFF
  50                 # libscap examples are not installed or really useful
  51                 -DBUILD_LIBSCAP_EXAMPLES=OFF
  52
  53                 # unbundle the deps
  54                 -DUSE_BUNDLED_DEPS=OFF
  55         )
  56
  57         cmake_src_configure
  58 }
  59
  60 src_install() {
  61         cmake_src_install
  62
  63         # remove sources
  64         rm -r "${ED}"/usr/src || die
  65
  66         # move bashcomp to the proper location
  67         dobashcomp "${ED}"/usr/etc/bash_completion.d/sysdig || die
  68         rm -r "${ED}"/usr/etc || die
  69 }