dev-util/sysdig/sysdig-0.15.1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 : ${CMAKE_MAKEFILE_GENERATOR:=ninja}
   7 MODULES_OPTIONAL_USE=modules
   8 inherit linux-mod bash-completion-r1 cmake-utils
   9
  10 DESCRIPTION="A system exploration and troubleshooting tool"
  11 HOMEPAGE="http://www.sysdig.org/"
  12 SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="+modules"
  18
  19 RDEPEND="
  20         app-misc/jq:0=
  21         dev-lang/luajit:2=
  22         >=dev-libs/jsoncpp-0.6_pre:0=
  23         dev-libs/libb64:0=
  24         sys-libs/ncurses:0=
  25         sys-libs/zlib:0=
  26         dev-libs/openssl:0=
  27         net-misc/curl:0="
  28 DEPEND="${RDEPEND}
  29         app-arch/xz-utils
  30         virtual/os-headers"
  31
  32 # needed for the kernel module
  33 CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
  34
  35 pkg_pretend() {
  36         linux-mod_pkg_setup
  37 }
  38
  39 pkg_setup() {
  40         linux-mod_pkg_setup
  41 }
  42
  43 src_prepare() {
  44         sed -i -e 's:-ggdb::' CMakeLists.txt || die
  45
  46         cmake-utils_src_prepare
  47 }
  48
  49 src_configure() {
  50         local mycmakeargs=(
  51                 # we will use linux-mod for that
  52                 -DBUILD_DRIVER=OFF
  53                 # libscap examples are not installed or really useful
  54                 -DBUILD_LIBSCAP_EXAMPLES=OFF
  55
  56                 # unbundle the deps
  57                 -DUSE_BUNDLED_DEPS=OFF
  58         )
  59
  60         cmake-utils_src_configure
  61
  62         # setup linux-mod ugliness
  63         MODULE_NAMES="sysdig-probe(extra:${S}/driver:)"
  64         BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
  65         BUILD_TARGETS="all"
  66
  67         if use modules; then
  68                 cmake-utils_src_make configure_driver
  69
  70                 cp "${BUILD_DIR}"/driver/Makefile.dkms driver/Makefile || die
  71         fi
  72 }
  73
  74 src_compile() {
  75         cmake-utils_src_compile
  76
  77         linux-mod_src_compile
  78 }
  79
  80 src_install() {
  81         cmake-utils_src_install
  82
  83         linux-mod_src_install
  84
  85         # remove sources
  86         rm -r "${ED%/}"/usr/src || die
  87
  88         # move bashcomp to the proper location
  89         dobashcomp "${ED%/}"/usr/etc/bash_completion.d/sysdig || die
  90         rm -r "${ED%/}"/usr/etc || die
  91 }