dev-util/splint/splint-3.1.2-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit autotools
   6
   7 DESCRIPTION="Check C programs for vulnerabilities and programming mistakes"
   8 HOMEPAGE="http://lclint.cs.virginia.edu/"
   9 SRC_URI="http://www.splint.org/downloads/${P}.src.tgz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 arm hppa ~ia64 ppc ppc64 sparc x86"
  14
  15 DEPEND="
  16         sys-devel/flex
  17 "
  18
  19 src_prepare() {
  20         # verbose compiler calls
  21         sed -i -e '/Compiling/d' src/Makefile.am || die
  22         # automake complains about trailing \
  23         sed -i -e '1600d' test/Makefile.am || die
  24         # do not install these header files twice
  25         sed -i -e '/\$(UnixHeaders)/s|stdio.h stdlib.h||g' lib/Makefile.am || die
  26
  27         eautoreconf
  28 }
  29
  30 src_configure() {
  31         # We do not need bison/yacc at all here
  32         # We definitely need libfl
  33         BISON=no LEXLIB=-lfl econf
  34 }
  35
  36 src_compile() {
  37         local subdir
  38         # skip test/ subdir
  39         for subdir in src lib imports doc; do
  40                 emake -j1 -C ${subdir}
  41         done
  42 }
  43
  44 src_test() {
  45         emake -C test
  46 }