dev-util/spirv-tools/spirv-tools-2020.4_pre20200429.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_PN=SPIRV-Tools
   7 CMAKE_ECLASS="cmake"
   8 PYTHON_COMPAT=( python3_{6,7,8} )
   9 inherit cmake-multilib python-any-r1
  10
  11 if [[ ${PV} == *9999* ]]; then
  12         EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
  13         inherit git-r3
  14 else
  15         SNAPSHOT_COMMIT="49ca250b44c633ba7cb8897002e62781a451421c"
  16         SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/${SNAPSHOT_COMMIT}.tar.gz -> ${P}.tar.gz"
  17         KEYWORDS="~amd64 ~ppc64 ~x86"
  18         S="${WORKDIR}"/${MY_PN}-${SNAPSHOT_COMMIT}
  19 fi
  20
  21 DESCRIPTION="Provides an API and commands for processing SPIR-V modules"
  22 HOMEPAGE="https://github.com/KhronosGroup/SPIRV-Tools"
  23
  24 LICENSE="Apache-2.0"
  25 SLOT="0"
  26 # Tests fail upon finding symbols that do not match a regular expression
  27 # in the generated library. Easily hit with non-standard compiler flags
  28 RESTRICT="test"
  29 COMMON_DEPEND=">=dev-util/spirv-headers-1.5.3"
  30 DEPEND="${COMMON_DEPEND}"
  31 RDEPEND=""
  32 BDEPEND="${PYTHON_DEPS}
  33         ${COMMON_DEPEND}"
  34
  35 multilib_src_configure() {
  36         local mycmakeargs=(
  37                 "-DSPIRV-Headers_SOURCE_DIR=/usr/"
  38                 "-DSPIRV_WERROR=OFF"
  39         )
  40
  41         cmake_src_configure
  42 }