dev-util/scanmem/scanmem-0.15.3.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 PYTHON_COMPAT=( python{2_7,3_4,3_5} )
   7
   8 inherit autotools eutils python-single-r1
   9
  10 DESCRIPTION="Locate and modify variables in executing processes"
  11 HOMEPAGE="https://github.com/scanmem/scanmem"
  12 SRC_URI="https://github.com/scanmem/scanmem/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="GPL-3"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="gui"
  18
  19 DEPEND="sys-libs/readline:="
  20 RDEPEND="${DEPEND}
  21         gui? (
  22                 ${PYTHON_DEPS}
  23                 dev-python/pygobject:3
  24                 sys-auth/polkit
  25         )"
  26
  27 REQUIRED_USE="gui? ( ${PYTHON_REQUIRED_USE} )"
  28
  29 pkg_setup() {
  30         use gui && python-single-r1_pkg_setup
  31 }
  32
  33 src_prepare() {
  34         sed -i "/CFLAGS/d" Makefile.am || die
  35
  36         eautoreconf
  37 }
  38
  39 src_configure() {
  40         econf \
  41                 --docdir="/usr/share/doc/${PF}" \
  42                 $(use_enable gui)
  43 }
  44
  45 src_install() {
  46         default
  47
  48         if use gui ; then
  49                 docinto gui
  50                 dodoc gui/{README,TODO}
  51                 python_fix_shebang "${D}"
  52         fi
  53 }