dev-util/pkgconfig/pkgconfig-0.28-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit eutils flag-o-matic libtool multilib multilib-minimal
   7
   8 MY_P=pkg-config-${PV}
   9
  10 if [[ ${PV} == *9999* ]]; then
  11         EGIT_REPO_URI="https://anongit.freedesktop.org/git/pkg-config.git"
  12         inherit autotools git-2
  13 else
  14         KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 s390 sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  15         SRC_URI="https://pkgconfig.freedesktop.org/releases/${MY_P}.tar.gz"
  16 fi
  17
  18 DESCRIPTION="Package config system that manages compile/link flags"
  19 HOMEPAGE="https://pkgconfig.freedesktop.org/wiki/"
  20
  21 LICENSE="GPL-2"
  22 SLOT="0"
  23 IUSE="elibc_FreeBSD elibc_glibc hardened internal-glib"
  24
  25 RDEPEND="!internal-glib? ( >=dev-libs/glib-2.34.3[${MULTILIB_USEDEP}] )
  26         !dev-util/pkgconf[pkg-config]
  27         !dev-util/pkg-config-lite
  28         !dev-util/pkgconfig-openbsd[pkg-config]"
  29 DEPEND="${RDEPEND}"
  30
  31 S=${WORKDIR}/${MY_P}
  32
  33 DOCS=( AUTHORS NEWS README )
  34
  35 src_prepare() {
  36         epatch "${FILESDIR}"/${P}-strip_system_library_dirs_reliably.patch
  37
  38         sed -i -e "s|^prefix=/usr\$|prefix=${EPREFIX}/usr|" check/simple.pc || die #434320
  39
  40         epatch_user
  41
  42         if [[ ${PV} == *9999* ]]; then
  43                 eautoreconf
  44         else
  45                 elibtoolize # Required for FreeMiNT wrt #333429
  46         fi
  47 }
  48
  49 multilib_src_configure() {
  50         local myconf
  51
  52         if use internal-glib; then
  53                 myconf+=' --with-internal-glib'
  54                 # non-glibc platforms use GNU libiconv, but configure needs to
  55                 # know about that not to get confused when it finds something
  56                 # outside the prefix too
  57                 if use prefix && use !elibc_glibc ; then
  58                         myconf+=" --with-libiconv=gnu"
  59                         # add the libdir for libtool, otherwise it'll make love with system
  60                         # installed libiconv
  61                         append-ldflags "-L${EPREFIX}/usr/$(get_libdir)"
  62                 fi
  63         else
  64                 if ! has_version --host-root dev-util/pkgconfig; then
  65                         export GLIB_CFLAGS="-I${EPREFIX}/usr/include/glib-2.0 -I${EPREFIX}/usr/$(get_libdir)/glib-2.0/include"
  66                         export GLIB_LIBS="-lglib-2.0"
  67                 fi
  68         fi
  69
  70         use ppc64 && use hardened && replace-flags -O[2-3] -O1
  71
  72         # Force using all the requirements when linking, so that needed -pthread
  73         # lines are inherited between libraries
  74         use elibc_FreeBSD && myconf+=' --enable-indirect-deps'
  75
  76         [[ ${PV} == *9999* ]] && myconf+=' --enable-maintainer-mode'
  77
  78         ECONF_SOURCE=${S} \
  79         econf \
  80                 --docdir="${EPREFIX}"/usr/share/doc/${PF}/html \
  81                 --with-system-include-path="${EPREFIX}"/usr/include \
  82                 --with-system-library-path="${EPREFIX}"/usr/$(get_libdir) \
  83                 ${myconf}
  84 }
  85
  86 multilib_src_install() {
  87         emake DESTDIR="${D}" install
  88
  89         if use prefix; then
  90                 # Add an explicit reference to $EPREFIX to PKG_CONFIG_PATH to
  91                 # simplify cross-prefix builds
  92                 echo "PKG_CONFIG_PATH=${EPREFIX}/usr/$(get_libdir)/pkgconfig:${EPREFIX}/usr/share/pkgconfig" >> "${T}"/99${PN}
  93                 doenvd "${T}"/99${PN}
  94         fi
  95 }