dev-util/pkgconf/pkgconf-1.0.1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 if [[ ${PV} == "9999" ]] ; then
   8         EGIT_REPO_URI=( {https,git}://github.com/pkgconf/${PN}.git )
   9         inherit autotools git-r3
  10 else
  11         SRC_URI="https://github.com/pkgconf/pkgconf/releases/download/${P}/${P}.tar.gz"
  12         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh
  13                 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux
  14                 ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc64-solaris ~x64-solaris"
  15 fi
  16
  17 inherit multilib-minimal
  18
  19 DESCRIPTION="pkg-config compatible replacement with no dependencies other than ANSI C89"
  20 HOMEPAGE="https://github.com/pkgconf/pkgconf"
  21
  22 LICENSE="BSD-1"
  23 SLOT="0"
  24 IUSE="+pkg-config strict"
  25
  26 DEPEND=""
  27 RDEPEND="${DEPEND}
  28         pkg-config? (
  29                 !dev-util/pkgconfig
  30                 !dev-util/pkg-config-lite
  31                 !dev-util/pkgconfig-openbsd[pkg-config]
  32         )"
  33
  34 MULTILIB_CHOST_TOOLS=(
  35         /usr/bin/pkgconf
  36 )
  37
  38 src_prepare() {
  39         default
  40
  41         [[ ${PV} == "9999" ]] && eautoreconf
  42         if use pkg-config; then
  43                 MULTILIB_CHOST_TOOLS+=(
  44                         /usr/bin/pkg-config
  45                 )
  46         fi
  47 }
  48
  49 multilib_src_configure() {
  50         ECONF_SOURCE=${S} \
  51         econf $(use_enable strict)
  52 }
  53
  54 multilib_src_install() {
  55         default
  56
  57         if use pkg-config; then
  58                 dosym pkgconf /usr/bin/pkg-config
  59         else
  60                 rm "${ED%/}"/usr/share/aclocal/pkg.m4 || die
  61         fi
  62 }