dev-util/lldb/lldb-9.0.1_rc3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
   7 inherit cmake-utils llvm llvm.org multiprocessing python-single-r1 \
   8         toolchain-funcs
   9
  10 DESCRIPTION="The LLVM debugger"
  11 HOMEPAGE="https://llvm.org/"
  12 LLVM_COMPONENTS=( lldb )
  13 LLVM_TEST_COMPONENTS=( llvm/lib/Testing/Support llvm/utils/unittest )
  14 llvm.org_set_globals
  15
  16 LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  19 IUSE="libedit ncurses +python test"
  20 REQUIRED_USE=${PYTHON_REQUIRED_USE}
  21 RESTRICT="!test? ( test )"
  22
  23 RDEPEND="
  24         libedit? ( dev-libs/libedit:0= )
  25         ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
  26         python? ( dev-python/six[${PYTHON_USEDEP}]
  27                 ${PYTHON_DEPS} )
  28         ~sys-devel/clang-${PV}[xml]
  29         ~sys-devel/llvm-${PV}
  30         !<sys-devel/llvm-4.0"
  31 DEPEND="${RDEPEND}"
  32 BDEPEND="
  33         python? ( >=dev-lang/swig-3.0.11 )
  34         test? (
  35                 ~dev-python/lit-${PV}[${PYTHON_USEDEP}]
  36                 sys-devel/lld )
  37         ${PYTHON_DEPS}"
  38
  39 # least intrusive of all
  40 CMAKE_BUILD_TYPE=RelWithDebInfo
  41
  42 pkg_setup() {
  43         LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
  44         python-single-r1_pkg_setup
  45 }
  46
  47 src_configure() {
  48         local mycmakeargs=(
  49                 -DLLDB_DISABLE_CURSES=$(usex !ncurses)
  50                 -DLLDB_DISABLE_LIBEDIT=$(usex !libedit)
  51                 -DLLDB_DISABLE_PYTHON=$(usex !python)
  52                 -DLLDB_USE_SYSTEM_SIX=1
  53                 -DLLVM_ENABLE_TERMINFO=$(usex ncurses)
  54
  55                 -DLLDB_INCLUDE_TESTS=$(usex test)
  56
  57                 # TODO: fix upstream to detect this properly
  58                 -DHAVE_LIBDL=ON
  59                 -DHAVE_LIBPTHREAD=ON
  60
  61                 # normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
  62                 # and TERMINFO_LIBS... so just force FindCurses.cmake to use
  63                 # ncurses with complete library set (including autodetection
  64                 # of -ltinfo)
  65                 -DCURSES_NEED_NCURSES=ON
  66         )
  67         use test && mycmakeargs+=(
  68                 -DLLVM_BUILD_TESTS=$(usex test)
  69                 # compilers for lit tests
  70                 -DLLDB_TEST_C_COMPILER="$(type -P clang)"
  71                 -DLLDB_TEST_CXX_COMPILER="$(type -P clang++)"
  72
  73                 -DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
  74                 -DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
  75                 -DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}"
  76         )
  77
  78         cmake-utils_src_configure
  79 }
  80
  81 src_test() {
  82         local -x LIT_PRESERVES_TMP=1
  83         cmake-utils_src_make check-lldb-lit
  84         use python && cmake-utils_src_make check-lldb
  85 }
  86
  87 src_install() {
  88         cmake-utils_src_install
  89
  90         use python && python_optimize
  91 }