dev-util/lldb/lldb-11.0.0.9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python{2_7,3_{6,7}} )
   7 inherit cmake-utils llvm llvm.org multiprocessing python-single-r1 \
   8         toolchain-funcs
   9
  10 DESCRIPTION="The LLVM debugger"
  11 HOMEPAGE="https://llvm.org/"
  12 LLVM_COMPONENTS=( lldb )
  13 LLVM_TEST_COMPONENTS=( llvm/lib/Testing/Support llvm/utils/unittest )
  14 llvm.org_set_globals
  15
  16 LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
  17 SLOT="0"
  18 KEYWORDS=""
  19 IUSE="libedit lzma ncurses +python test"
  20 REQUIRED_USE=${PYTHON_REQUIRED_USE}
  21 RESTRICT="!test? ( test )"
  22
  23 RDEPEND="
  24         libedit? ( dev-libs/libedit:0= )
  25         lzma? ( app-arch/xz-utils:= )
  26         ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
  27         python? ( dev-python/six[${PYTHON_USEDEP}]
  28                 ${PYTHON_DEPS} )
  29         ~sys-devel/clang-${PV}[xml]
  30         ~sys-devel/llvm-${PV}
  31         !<sys-devel/llvm-4.0"
  32 DEPEND="${RDEPEND}"
  33 BDEPEND="
  34         python? ( >=dev-lang/swig-3.0.11 )
  35         test? (
  36                 ~dev-python/lit-${PV}[${PYTHON_USEDEP}]
  37                 sys-devel/lld )
  38         ${PYTHON_DEPS}"
  39
  40 # least intrusive of all
  41 CMAKE_BUILD_TYPE=RelWithDebInfo
  42
  43 pkg_setup() {
  44         LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
  45         python-single-r1_pkg_setup
  46 }
  47
  48 src_configure() {
  49         local mycmakeargs=(
  50                 -DLLDB_ENABLE_CURSES=$(usex ncurses)
  51                 -DLLDB_ENABLE_LIBEDIT=$(usex libedit)
  52                 -DLLDB_ENABLE_PYTHON=$(usex python)
  53                 -DLLDB_ENABLE_LZMA=$(usex lzma)
  54                 -DLLDB_USE_SYSTEM_SIX=1
  55                 -DLLVM_ENABLE_TERMINFO=$(usex ncurses)
  56
  57                 -DLLDB_INCLUDE_TESTS=$(usex test)
  58
  59                 -DCLANG_LINK_CLANG_DYLIB=ON
  60                 # TODO: fix upstream to detect this properly
  61                 -DHAVE_LIBDL=ON
  62                 -DHAVE_LIBPTHREAD=ON
  63
  64                 # normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
  65                 # and TERMINFO_LIBS... so just force FindCurses.cmake to use
  66                 # ncurses with complete library set (including autodetection
  67                 # of -ltinfo)
  68                 -DCURSES_NEED_NCURSES=ON
  69         )
  70         use test && mycmakeargs+=(
  71                 -DLLVM_BUILD_TESTS=$(usex test)
  72                 # compilers for lit tests
  73                 -DLLDB_TEST_C_COMPILER="$(type -P clang)"
  74                 -DLLDB_TEST_CXX_COMPILER="$(type -P clang++)"
  75
  76                 -DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
  77                 -DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
  78                 -DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}"
  79         )
  80
  81         cmake-utils_src_configure
  82 }
  83
  84 src_test() {
  85         local -x LIT_PRESERVES_TMP=1
  86         cmake-utils_src_make check-lldb-lit
  87         use python && cmake-utils_src_make check-lldb
  88 }
  89
  90 src_install() {
  91         cmake-utils_src_install
  92         find "${D}" -name '*.a' -delete || die
  93
  94         use python && python_optimize
  95 }