dev-util/lldb/lldb-11.0.0.9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 inherit cmake-utils llvm llvm.org multiprocessing python-single-r1 \
   8         toolchain-funcs
   9
  10 DESCRIPTION="The LLVM debugger"
  11 HOMEPAGE="https://llvm.org/"
  12 LLVM_COMPONENTS=( lldb )
  13 LLVM_TEST_COMPONENTS=( llvm/lib/Testing/Support llvm/utils/unittest )
  14 llvm.org_set_globals
  15
  16 LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
  17 SLOT="0"
  18 KEYWORDS=""
  19 IUSE="libedit lzma ncurses +python test"
  20 REQUIRED_USE=${PYTHON_REQUIRED_USE}
  21 RESTRICT="!test? ( test )"
  22
  23 RDEPEND="
  24         libedit? ( dev-libs/libedit:0= )
  25         lzma? ( app-arch/xz-utils:= )
  26         ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
  27         python? (
  28                 $(python_gen_cond_dep '
  29                         dev-python/six[${PYTHON_MULTI_USEDEP}]
  30                 ')
  31                 ${PYTHON_DEPS}
  32         )
  33         ~sys-devel/clang-${PV}[xml]
  34         ~sys-devel/llvm-${PV}
  35         !<sys-devel/llvm-4.0"
  36 DEPEND="${RDEPEND}"
  37 BDEPEND="
  38         python? ( >=dev-lang/swig-3.0.11 )
  39         test? (
  40                 $(python_gen_cond_dep "
  41                         ~dev-python/lit-${PV}[\${PYTHON_MULTI_USEDEP}]
  42                 ")
  43                 sys-devel/lld )
  44         ${PYTHON_DEPS}"
  45
  46 # least intrusive of all
  47 CMAKE_BUILD_TYPE=RelWithDebInfo
  48
  49 pkg_setup() {
  50         LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
  51         python-single-r1_pkg_setup
  52 }
  53
  54 src_configure() {
  55         local mycmakeargs=(
  56                 -DLLDB_ENABLE_CURSES=$(usex ncurses)
  57                 -DLLDB_ENABLE_LIBEDIT=$(usex libedit)
  58                 -DLLDB_ENABLE_PYTHON=$(usex python)
  59                 -DLLDB_ENABLE_LZMA=$(usex lzma)
  60                 -DLLDB_USE_SYSTEM_SIX=1
  61                 -DLLVM_ENABLE_TERMINFO=$(usex ncurses)
  62
  63                 -DLLDB_INCLUDE_TESTS=$(usex test)
  64
  65                 -DCLANG_LINK_CLANG_DYLIB=ON
  66                 # TODO: fix upstream to detect this properly
  67                 -DHAVE_LIBDL=ON
  68                 -DHAVE_LIBPTHREAD=ON
  69
  70                 # normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
  71                 # and TERMINFO_LIBS... so just force FindCurses.cmake to use
  72                 # ncurses with complete library set (including autodetection
  73                 # of -ltinfo)
  74                 -DCURSES_NEED_NCURSES=ON
  75         )
  76         use test && mycmakeargs+=(
  77                 -DLLVM_BUILD_TESTS=$(usex test)
  78                 # compilers for lit tests
  79                 -DLLDB_TEST_COMPILER="$(type -P clang)"
  80
  81                 -DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
  82                 -DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
  83                 -DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}"
  84         )
  85
  86         cmake-utils_src_configure
  87 }
  88
  89 src_test() {
  90         local -x LIT_PRESERVES_TMP=1
  91         cmake-utils_src_make check-lldb-lit
  92         use python && cmake-utils_src_make check-lldb
  93 }
  94
  95 src_install() {
  96         cmake-utils_src_install
  97         find "${D}" -name '*.a' -delete || die
  98
  99         use python && python_optimize
 100 }