dev-util/libabigail/libabigail-1.6.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{7,8} )
   7
   8 inherit autotools python-any-r1 out-of-source
   9
  10 DESCRIPTION="Suite of tools for checking ABI differences between ELF objects"
  11 HOMEPAGE="https://sourceware.org/libabigail/"
  12 SRC_URI="https://mirrors.kernel.org/sourceware/libabigail/${P}.tar.gz"
  13
  14 LICENSE="LGPL-3+"
  15 SLOT="0"
  16 KEYWORDS="~amd64"
  17 IUSE="doc test"
  18 RESTRICT="!test? ( test )"
  19
  20 RDEPEND="
  21         dev-libs/elfutils:=
  22         dev-libs/libxml2:2="
  23 DEPEND="${RDEPEND}"
  24 BDEPEND="
  25         doc? (
  26                 app-doc/doxygen
  27                 dev-python/sphinx
  28                 sys-apps/texinfo
  29         )
  30         test? ( ${PYTHON_DEPS} )"
  31
  32 src_prepare() {
  33         default
  34         # need to run our autotools, due to ltmain.sh including Redhat calls:
  35         # cannot read spec file '/usr/lib/rpm/redhat/redhat-hardened-ld': No such file or directory
  36         eautoreconf
  37 }
  38
  39 my_src_configure() {
  40         econf \
  41                 --disable-deb \
  42                 --disable-fedabipkgdiff \
  43                 --disable-rpm \
  44                 --disable-static \
  45                 --disable-zip-archive \
  46                 --enable-bash-completion \
  47                 --enable-cxx11 \
  48                 --enable-python3 \
  49                 $(use_enable doc apidoc) \
  50                 $(use_enable doc manual)
  51 }
  52
  53 my_src_compile() {
  54         default
  55         use doc && emake doc
  56 }
  57
  58 my_src_install() {
  59         emake DESTDIR="${D}" install
  60
  61         if use doc; then
  62                 doman doc/manuals/man/*
  63                 doinfo doc/manuals/texinfo/abigail.info
  64
  65                 dodoc -r doc/manuals/html
  66
  67                 docinto html/api
  68                 dodoc -r doc/api/html/.
  69         fi
  70 }
  71
  72 my_src_install_all() {
  73         einstalldocs
  74
  75         # no static archives
  76         find "${D}" -name '*.la' -delete || die
  77 }