dev-qt/qttest: stable 5.14.2 for ppc, bug #719732
[gentoo.git] / dev-util / kdevelop / kdevelop-5.4.6.ebuild
1 # Copyright 1999-2020 Gentoo Authors
2 # Distributed under the terms of the GNU General Public License v2
3
4 EAPI=7
5
6 ECM_HANDBOOK="forceoptional"
7 ECM_TEST="true"
8 KDE_APPS_MINIMAL=19.04.3
9 KFMIN=5.60.0
10 QTMIN=5.12.3
11 VIRTUALDBUS_TEST="true"
12 VIRTUALX_REQUIRED="test"
13 inherit ecm kde.org
14
15 if [[ ${KDE_BUILD_TYPE} = release ]]; then
16         KEYWORDS="amd64 x86"
17 fi
18
19 DESCRIPTION="Integrated Development Environment, supporting KF5/Qt, C/C++ and much more"
20 HOMEPAGE="https://www.kdevelop.org/"
21
22 LICENSE="GPL-2 LGPL-2"
23 SLOT="5/54" # look at KDEVELOP_SOVERSION inside CMakeLists.txt
24 IUSE="+gdbui hex +plasma +qmake reviewboard subversion webkit"
25
26 COMMON_DEPEND="
27         >=kde-frameworks/karchive-${KFMIN}:5
28         >=kde-frameworks/kbookmarks-${KFMIN}:5
29         >=kde-frameworks/kcmutils-${KFMIN}:5
30         >=kde-frameworks/kcodecs-${KFMIN}:5
31         >=kde-frameworks/kcompletion-${KFMIN}:5
32         >=kde-frameworks/kconfig-${KFMIN}:5
33         >=kde-frameworks/kconfigwidgets-${KFMIN}:5
34         >=kde-frameworks/kcoreaddons-${KFMIN}:5
35         >=kde-frameworks/kcrash-${KFMIN}:5
36         >=kde-frameworks/kdeclarative-${KFMIN}:5
37         >=kde-frameworks/kguiaddons-${KFMIN}:5
38         >=kde-frameworks/ki18n-${KFMIN}:5
39         >=kde-frameworks/kiconthemes-${KFMIN}:5
40         >=kde-frameworks/kio-${KFMIN}:5
41         >=kde-frameworks/kitemmodels-${KFMIN}:5
42         >=kde-frameworks/kitemviews-${KFMIN}:5
43         >=kde-frameworks/kjobwidgets-${KFMIN}:5
44         >=kde-frameworks/knewstuff-${KFMIN}:5
45         >=kde-frameworks/knotifications-${KFMIN}:5
46         >=kde-frameworks/knotifyconfig-${KFMIN}:5
47         >=kde-frameworks/kparts-${KFMIN}:5
48         >=kde-frameworks/kservice-${KFMIN}:5
49         >=kde-frameworks/ktexteditor-${KFMIN}:5
50         >=kde-frameworks/ktextwidgets-${KFMIN}:5
51         >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
52         >=kde-frameworks/kwindowsystem-${KFMIN}:5
53         >=kde-frameworks/kxmlgui-${KFMIN}:5
54         >=kde-frameworks/sonnet-${KFMIN}:5
55         >=kde-frameworks/threadweaver-${KFMIN}:5
56         >=kde-apps/libkomparediff2-${KDE_APPS_MINIMAL}:5
57         >=dev-qt/qtdbus-${QTMIN}:5
58         >=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
59         >=dev-qt/qtgui-${QTMIN}:5
60         >=dev-qt/qthelp-${QTMIN}:5
61         >=dev-qt/qtnetwork-${QTMIN}:5
62         >=dev-qt/qttest-${QTMIN}:5
63         >=dev-qt/qtwidgets-${QTMIN}:5
64         >=dev-qt/qtxml-${QTMIN}:5
65         dev-libs/grantlee:5
66         >=dev-util/astyle-3.1:=
67         >=sys-devel/clang-3.8.0:=
68         gdbui? ( >=kde-plasma/libksysguard-5.16.5:5 )
69         hex? ( app-editors/okteta:5 )
70         plasma? (
71                 >=kde-frameworks/krunner-${KFMIN}:5
72                 >=kde-frameworks/plasma-${KFMIN}:5
73         )
74         qmake? ( dev-util/kdevelop-pg-qt:5 )
75         reviewboard? ( >=kde-frameworks/purpose-${KFMIN}:5 )
76         subversion? (
77                 dev-libs/apr:1
78                 dev-libs/apr-util:1
79                 dev-vcs/subversion
80         )
81         webkit? ( >=dev-qt/qtwebkit-5.212.0_pre20180120:5 )
82         !webkit? ( >=dev-qt/qtwebengine-${QTMIN}:5[widgets] )
83 "
84 DEPEND="${COMMON_DEPEND}
85         dev-libs/boost
86         >=dev-qt/qtconcurrent-${QTMIN}:5
87 "
88 RDEPEND="${COMMON_DEPEND}
89         >=kde-apps/kapptemplate-${KDE_APPS_MINIMAL}:5
90         >=kde-apps/kio-extras-${KDE_APPS_MINIMAL}:5
91         >=dev-qt/qdbus-${QTMIN}:5
92         >=dev-qt/qtquickcontrols-${QTMIN}:5
93         >=dev-qt/qtquickcontrols2-${QTMIN}:5
94         dev-util/ninja
95         >=sys-devel/gdb-7.0[python]
96         reviewboard? ( >=kde-apps/ktp-accounts-kcm-${KDE_APPS_MINIMAL}:5 )
97         !dev-util/kdevelop-clang-tidy
98 "
99
100 RESTRICT+=" test"
101 # see bug 366471
102
103 src_configure() {
104         local mycmakeargs=(
105                 $(cmake_use_find_package gdbui KF5SysGuard)
106                 -DBUILD_executeplasmoid=$(usex plasma)
107                 $(cmake_use_find_package plasma KF5Plasma)
108                 $(cmake_use_find_package hex OktetaKastenControllers)
109                 $(cmake_use_find_package qmake KDevelop-PG-Qt)
110                 $(cmake_use_find_package reviewboard KF5Purpose)
111                 $(cmake_use_find_package subversion SubversionLibrary)
112                 $(cmake_use_find_package !webkit Qt5WebEngineWidgets)
113         )
114
115         use reviewboard || mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_KDEExperimentalPurpose=ON )
116
117         ecm_src_configure
118 }
119
120 pkg_postinst() {
121         ecm_pkg_postinst
122
123         if ! has_version "kde-apps/konsole" ; then
124                 elog "For konsole view, please install kde-apps/konsole"
125         fi
126
127         if ! has_version "dev-util/cppcheck" ; then
128                 elog "For static C/C++ code analysis support, please install dev-util/cppcheck"
129         fi
130
131         if ! has_version "dev-util/heaptrack[qt5]" ; then
132                 elog "For heap memory profiling support, please install dev-util/heaptrack"
133         fi
134
135         if ! has_version "dev-util/clazy" ; then
136                 elog "For static C++ Qt code analysis support, please install dev-util/clazy"
137         fi
138 }