dev-util/kbuild/kbuild-0.1.9998_pre20120806.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=4
   6
   7 inherit eutils autotools toolchain-funcs
   8
   9 MY_P=kBuild-${PV/_/-}-src
  10 DESCRIPTION="A makefile framework for writing simple makefiles for complex tasks"
  11 HOMEPAGE="http://svn.netlabs.org/kbuild/wiki"
  12 #SRC_URI="ftp://ftp.netlabs.org/pub/${PN}/${MY_P}.tar.gz"
  13 SRC_URI="https://dev.gentoo.org/~polynomial-c/${MY_P}.tar.xz"
  14
  15 LICENSE="GPL-3"
  16 SLOT="0"
  17 KEYWORDS="amd64 x86"
  18 IUSE=""
  19
  20 DEPEND="sys-devel/flex
  21         sys-devel/gettext
  22         virtual/yacc"
  23 RDEPEND=""
  24
  25 S=${WORKDIR}/${MY_P/-src}
  26
  27 src_prepare() {
  28         rm -rf "${S}/kBuild/bin"
  29
  30         epatch "${FILESDIR}/${PN}-unknown-configure-opt.patch" \
  31                 "${FILESDIR}/${PN}-glibc-2.10.patch" \
  32                 "${FILESDIR}/${PN}-0.1.5-gentoo-docdir.patch" \
  33                 "${FILESDIR}/${PN}-0.1.9998_pre20120806-qa.patch" \
  34                 "${FILESDIR}/${PN}-0.1.9998_pre20110817-kash-link-pthread.patch" \
  35                 "${FILESDIR}/${PN}-0.1.9998_pre20110817-gold.patch" \
  36                 "${FILESDIR}/${PN}-0.1.9998_pre20110817-gcc-4.7.patch"
  37
  38         cd "${S}/src/kmk" || die
  39         eautoreconf
  40         cd "${S}/src/sed" || die
  41         # AM_CONFIG_HEADER is obsolete since automake-1.13 (bug #467104)
  42         sed 's@AM_CONFIG_HEADER@AC_CONFIG_HEADERS@' -i configure.ac || die
  43         eautoreconf
  44
  45         sed -e "s@_LDFLAGS\.${ARCH}*.*=@& ${LDFLAGS}@g" \
  46                 -i "${S}"/Config.kmk || die #332225
  47         tc-export CC RANLIB #AR does not work here
  48 }
  49
  50 src_compile() {
  51         kBuild/env.sh --full make -f bootstrap.gmk AUTORECONF=true AR="$(tc-getAR)" \
  52                 || die "bootstrap failed"
  53 }
  54
  55 src_install() {
  56         kBuild/env.sh kmk NIX_INSTALL_DIR=/usr PATH_INS="${D}" install \
  57                 || die "install failed"
  58 }