dev-util/kbuild/kbuild-0.1.9998.3127.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils autotools toolchain-funcs versionator
   7
   8 MY_P="${P}-src"
   9 DESCRIPTION="A makefile framework for writing simple makefiles for complex tasks"
  10 HOMEPAGE="http://svn.netlabs.org/kbuild/wiki"
  11 #SRC_URI="ftp://ftp.netlabs.org/pub/${PN}/${MY_P}.tar.gz"
  12 SRC_URI="https://dev.gentoo.org/~polynomial-c/${MY_P}.tar.xz"
  13
  14 LICENSE="GPL-3+"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86 ~amd64-fbsd ~x86-fbsd"
  17 IUSE=""
  18
  19 DEPEND="
  20         sys-apps/texinfo
  21         sys-devel/flex
  22         sys-devel/gettext
  23         virtual/yacc
  24 "
  25 RDEPEND=""
  26
  27 PATCHES=(
  28         "${FILESDIR}/${PN}-unknown-configure-opt.patch"
  29         "${FILESDIR}/${PN}-0.1.5-gentoo-docdir.patch"
  30         "${FILESDIR}/${PN}-0.1.9998_pre20120806-qa.patch"
  31         "${FILESDIR}/${PN}-0.1.9998_pre20110817-kash-link-pthread.patch"
  32         "${FILESDIR}/${PN}-0.1.9998_pre20171020-gold.patch"
  33 )
  34
  35 src_prepare() {
  36         rm -rf "${S}/kBuild/bin"
  37
  38         default
  39
  40         mv src/kmk/configure.{in,ac} || die
  41
  42         # Add a file with the svn revision this package was pulled from
  43         printf '%s\n' "KBUILD_SVN_REV := $(get_version_component_range 4)" \
  44                 > SvnInfo.kmk || die
  45
  46         cd "${S}/src/kmk" || die
  47         eautoreconf
  48         cd "${S}/src/sed" || die
  49         # AM_CONFIG_HEADER is obsolete since automake-1.13 (bug #467104)
  50         sed 's@AM_CONFIG_HEADER@AC_CONFIG_HEADERS@' -i configure.ac || die
  51         eautoreconf
  52
  53         sed -e "s@_LDFLAGS\.$(tc-arch)*.*=@& ${LDFLAGS}@g" \
  54                 -i "${S}"/Config.kmk || die #332225
  55         tc-export CC RANLIB #AR does not work here
  56 }
  57
  58 src_compile() {
  59         kBuild/env.sh --full emake -f bootstrap.gmk AUTORECONF=true AR="$(tc-getAR)" \
  60                 || die "bootstrap failed"
  61 }
  62
  63 src_install() {
  64         kBuild/env.sh kmk NIX_INSTALL_DIR=/usr PATH_INS="${D}" install \
  65                 || die "install failed"
  66 }