dev-util/jenkins-bin/jenkins-bin-2.38.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 inherit user systemd
   8
   9 DESCRIPTION="Extensible continuous integration server"
  10 HOMEPAGE="http://jenkins-ci.org/"
  11 LICENSE="MIT"
  12 SRC_URI="http://mirrors.jenkins-ci.org/war/${PV}/${PN/-bin/}.war -> ${P}.war"
  13 RESTRICT="mirror"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86 ~amd64-linux"
  16 IUSE=""
  17
  18 RDEPEND="media-fonts/dejavu
  19         media-libs/freetype
  20         !dev-util/jenkins-bin:lts
  21         >=virtual/jre-1.7.0"
  22
  23 S=${WORKDIR}
  24
  25 JENKINS_DIR=/var/lib/jenkins
  26
  27 pkg_setup() {
  28         enewgroup jenkins
  29         enewuser jenkins -1 -1 ${JENKINS_DIR} jenkins
  30 }
  31
  32 src_install() {
  33         keepdir /var/log/jenkins ${JENKINS_DIR}/backup ${JENKINS_DIR}/home
  34
  35         insinto /opt/jenkins
  36         newins "${DISTDIR}"/${P}.war ${PN/-bin/}.war
  37
  38         insinto /etc/logrotate.d
  39         newins "${FILESDIR}"/${PN}-r1.logrotate ${PN/-bin/}
  40
  41         newinitd "${FILESDIR}"/${PN}.init2 jenkins
  42         newconfd "${FILESDIR}"/${PN}.confd jenkins
  43
  44         systemd_newunit "${FILESDIR}"/${PN}.service jenkins.service
  45
  46         fowners jenkins:jenkins /var/log/jenkins ${JENKINS_DIR} ${JENKINS_DIR}/home ${JENKINS_DIR}/backup
  47 }