dev-util/indent/indent-2.2.11_p5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools eutils
   6
   7 DESCRIPTION="Indent program source files"
   8 HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
   9 SRC_URI="
  10         https://dev.gentoo.org/~jer/${P/_p*/}.tar.gz
  11         http://http.debian.net/debian/pool/main/i/${PN}/${PN}_${PV/_p*/}-${PV/*_p/}.debian.tar.xz
  12 "
  13
  14 LICENSE="GPL-3"
  15 SLOT="0"
  16 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
  17 IUSE="nls"
  18
  19 DEPEND="
  20         nls? ( sys-devel/gettext )
  21         app-text/texi2html
  22 "
  23 RDEPEND="
  24         nls? ( virtual/libintl )
  25 "
  26 PATCHES=(
  27         "${FILESDIR}"/${P/_p*/}-segfault.patch
  28         "${FILESDIR}"/${P/_p*/}-texi2html-5.patch
  29         "${FILESDIR}"/${P/_p*/}-ac_config_headers.patch
  30         "${FILESDIR}"/${P/_p*/}-linguas.patch
  31 )
  32 S=${WORKDIR}/${P/_p*/}
  33
  34 src_prepare() {
  35         default
  36
  37         eapply "${WORKDIR}"/debian/patches/*.patch
  38
  39         local pofile
  40         for pofile in po/zh_TW*; do
  41                 mv ${pofile} ${pofile/.Big5} || die
  42         done
  43
  44         eautoreconf
  45 }
  46
  47 src_configure() {
  48         strip-linguas -i po/
  49
  50         econf $(use_enable nls)
  51 }
  52
  53 src_test() {
  54         emake -C regression/
  55 }
  56
  57 src_install() {
  58         # htmldir as set in configure is ignored in doc/Makefile*
  59         emake DESTDIR="${D}" htmldir="${EPREFIX}/usr/share/doc/${PF}/html" install
  60         dodoc AUTHORS NEWS README ChangeLog ChangeLog-1990 ChangeLog-1998 ChangeLog-2001
  61 }