dev-util/indent/indent-2.2.11-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit autotools eutils
   6
   7 DESCRIPTION="Indent program source files"
   8 HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
   9 SRC_URI="https://dev.gentoo.org/~jer/${P}.tar.gz"
  10
  11 LICENSE="GPL-3"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
  14 IUSE="nls"
  15
  16 DEPEND="
  17         nls? ( sys-devel/gettext )
  18         app-text/texi2html
  19 "
  20 RDEPEND="
  21         nls? ( virtual/libintl )
  22 "
  23
  24 src_prepare() {
  25         # Fix bug #94837
  26         local pofile
  27         for pofile in po/zh_TW*; do
  28                 mv ${pofile} ${pofile/.Big5} || die
  29         done
  30         sed -i po/LINGUAS -e 's|zh_TW\.Big5|zh_TW|g' || die
  31
  32         epatch \
  33                 "${FILESDIR}"/${P}-segfault.patch \
  34                 "${FILESDIR}"/${P}-texi2html-5.patch
  35         sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac || die
  36
  37         eautoreconf
  38 }
  39
  40 src_configure() {
  41         econf $(use_enable nls)
  42 }
  43
  44 src_test() {
  45         emake -C regression/
  46 }
  47
  48 src_install() {
  49         # htmldir as set in configure is ignored in doc/Makefile*
  50         emake DESTDIR="${D}" htmldir="${EPREFIX}/usr/share/doc/${PF}/html" install
  51         dodoc AUTHORS NEWS README ChangeLog ChangeLog-1990 ChangeLog-1998 ChangeLog-2001
  52 }