dev-util/indent/indent-2.2.11-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit autotools eutils
   8
   9 DESCRIPTION="Indent program source files"
  10 HOMEPAGE="http://indent.isidore-it.eu/beautify.html https://www.gnu.org/software/indent/"
  11 SRC_URI="http://${PN}.isidore-it.eu/${P}.tar.gz"
  12
  13 LICENSE="GPL-3"
  14 SLOT="0"
  15 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
  16 IUSE="nls"
  17
  18 DEPEND="
  19         nls? ( sys-devel/gettext )
  20         app-text/texi2html
  21 "
  22 RDEPEND="
  23         nls? ( virtual/libintl )
  24 "
  25
  26 INDENT_LINGUAS="
  27         ca da de eo et fi fr gl hu it ja ko nl pl pt_BR ru sk sv tr zh_TW
  28 "
  29
  30 for indent_lingua in ${INDENT_LINGUAS}; do
  31         IUSE+=" linguas_${indent_lingua}"
  32 done
  33
  34 src_prepare() {
  35         # Fix bug #94837
  36         local pofile
  37         for pofile in po/zh_TW*; do
  38                 mv ${pofile} ${pofile/.Big5} || die
  39         done
  40         sed -i po/LINGUAS -e 's|zh_TW\.Big5|zh_TW|g' || die
  41
  42         epatch \
  43                 "${FILESDIR}"/${PV}-segfault.patch \
  44                 "${FILESDIR}"/${PV}-texi2html-5.patch
  45         sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac || die
  46         eautomake
  47 }
  48
  49 src_configure() {
  50         econf $(use_enable nls)
  51 }
  52
  53 src_test() {
  54         emake -C regression/
  55 }
  56
  57 src_install() {
  58         # htmldir as set in configure is ignored in doc/Makefile*
  59         emake DESTDIR="${D}" htmldir="${EPREFIX}/usr/share/doc/${PF}/html" install
  60         dodoc AUTHORS NEWS README ChangeLog ChangeLog-1990 ChangeLog-1998 ChangeLog-2001
  61 }