dev-util/gtk-doc-am/gtk-doc-am-1.25-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME_ORG_MODULE="gtk-doc"
   6
   7 inherit gnome.org
   8
   9 DESCRIPTION="Automake files from gtk-doc"
  10 HOMEPAGE="https://www.gtk.org/gtk-doc/"
  11
  12 LICENSE="GPL-2 FDL-1.1"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv s390 sparc x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  15
  16 RDEPEND=">=dev-lang/perl-5.18"
  17 DEPEND="${RDEPEND}
  18         virtual/pkgconfig
  19         !<dev-util/gtk-doc-${GNOME_ORG_PVP}
  20 "
  21 # This ebuild doesn't even compile anything, causing tests to fail when updating (bug #316071)
  22 RESTRICT="test"
  23
  24 src_configure() {
  25         # Duplicate autoconf checks so we don't have to call configure
  26         local PERL=$(type -P perl)
  27
  28         test -n "${PERL}" || die "Perl not found!"
  29         "${PERL}" -e "require v5.18.0" || die "perl >= 5.18.0 is required for gtk-doc"
  30
  31         # Replicate AC_SUBST
  32         sed -e "s:@PERL@:${PERL}:g" -e "s:@VERSION@:${PV}:g" \
  33                 "${S}/gtkdoc-rebase.in" > "${S}/gtkdoc-rebase" || die "sed failed!"
  34 }
  35
  36 src_compile() {
  37         :
  38 }
  39
  40 src_install() {
  41         dobin gtkdoc-rebase
  42
  43         insinto /usr/share/aclocal
  44         doins gtk-doc.m4
  45 }