dev-util/gnome-builder/gnome-builder-3.32.4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_{6,7} )
   6 VALA_MIN_API_VERSION="0.36"
   7 DISABLE_AUTOFORMATTING=1
   8 FORCE_PRINT_ELOG=1
   9
  10 inherit gnome.org gnome2-utils llvm meson python-single-r1 readme.gentoo-r1 vala virtualx xdg
  11
  12 DESCRIPTION="An IDE for writing GNOME-based software"
  13 HOMEPAGE="https://wiki.gnome.org/Apps/Builder"
  14 SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
  15
  16 # FIXME: Review licenses at some point
  17 LICENSE="GPL-3+ GPL-2+ LGPL-3+ LGPL-2+ MIT CC-BY-SA-3.0 CC0-1.0"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="clang +devhelp doc +glade gtk-doc spell sysprof test vala"
  21 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  22
  23 # When bumping, pay attention to all the included plugins/*/meson.build (and other) build files and the requirements within.
  24 # `grep -rI dependency * --include='meson.build'` can give a good initial idea for external deps and their double checking.
  25 # The listed RDEPEND order shold roughly match that output as well, with toplevel one first then sorted by file path.
  26 # Most plugins have no extra requirements and default to enabled; we need to handle the ones with extra requirements. Many of
  27 # them have optional runtime dependencies, for which we try to at least notify the user via DOC_CONTENTS (but not all small
  28 # things); `grep -rI -e 'command-pattern.*=' -e 'push_arg'` can give a (spammy) idea, plus python imports in try/except.
  29
  30 # FIXME: plugin_flatpak needs flatpak.pc >=0.8.0, ostree-1 and libsoup-2.4.pc >=2.52.0
  31 # Editorconfig needs old pcre, with vte migrating away, might want it optional or ported to pcre2?
  32 # An introspection USE flag of a dep is required if any introspection based language plugin wants to use it (grep for gi.repository). Last full check at 3.28.4
  33
  34 # TODO: Handle llvm slots via llvm.eclass; see plugins/clang/meson.build
  35 RDEPEND="
  36         >=dev-libs/libdazzle-3.31.90[introspection,vala?]
  37         >=dev-libs/glib-2.59.0:2
  38         >=x11-libs/gtk+-3.22.26:3[introspection]
  39         >=x11-libs/gtksourceview-4.0.0:4[introspection]
  40         >=dev-libs/json-glib-1.2.0
  41         >=dev-libs/jsonrpc-glib-3.19.91[vala?]
  42         >=x11-libs/pango-1.38.0
  43         $(python_gen_cond_dep '>=dev-libs/libpeas-1.22.0[python,${PYTHON_SINGLE_USEDEP}]')
  44         >=dev-libs/template-glib-3.28.0[introspection,vala?]
  45         >=x11-libs/vte-0.40.2:2.91[introspection,vala?]
  46         >=net-libs/webkit-gtk-2.12.0:4=[introspection]
  47         >=dev-libs/libxml2-2.9.0
  48         dev-libs/libgit2[ssh,threads]
  49         >=dev-libs/libgit2-glib-0.28[ssh]
  50         dev-libs/libpcre:3
  51
  52         >=dev-libs/gobject-introspection-1.54.0:=
  53         >=dev-python/pygobject-3.22.0:3[${PYTHON_USEDEP}]
  54         ${PYTHON_DEPS}
  55         clang? ( sys-devel/clang:= )
  56         devhelp? ( >=dev-util/devhelp-3.25.1:= )
  57         glade? ( >=dev-util/glade-3.22.0:3.10 )
  58         spell? ( >=app-text/gspell-1.8:0=
  59                 app-text/enchant:2 )
  60         sysprof? ( >=dev-util/sysprof-3.31.90[gtk] )
  61         vala? (
  62                 dev-lang/vala:=
  63                 $(vala_depend)
  64         )
  65 " # We use subslot operator dep on vala in addition to $(vala_depend), because we have _runtime_
  66 #   usage in vala-pack plugin and need it rebuilt before removing an older vala it was built against
  67 DEPEND="${RDEPEND}"
  68 # TODO: runtime ctags path finding..
  69
  70 # desktop-file-utils required for tests, but we have it in deptree for xdg update-desktop-database anyway, so be explicit and unconditional
  71 # appstream-glib needed for validation with appstream-util with FEATURES=test
  72 BDEPEND="
  73         doc? ( dev-python/sphinx )
  74         test? (
  75                 dev-libs/appstream-glib
  76                 sys-apps/dbus )
  77         dev-util/desktop-file-utils
  78         dev-util/glib-utils
  79         >=dev-util/meson-0.49.2
  80         >=sys-devel/gettext-0.19.8
  81         virtual/pkgconfig
  82 "
  83
  84 DOC_CONTENTS='gnome-builder can use various other dependencies on runtime to provide
  85 extra capabilities beyond these expressed via USE flags. Some of these
  86 that are currently available with packages include:
  87
  88 * dev-util/uncrustify and dev-python/autopep8 for various Code Beautifier
  89   plugin out of the box functionality.
  90 * dev-util/ctags with exuberant-ctags selected via "eselect ctags" for
  91   C, C++, Python, JavaScript, CSS, HTML and Ruby autocompletion, semantic
  92   highlighting and symbol resolving support.
  93 * dev-python/jedi and dev-python/lxml for more accurate Python
  94   autocompletion support.
  95 * dev-util/valgrind for integration with valgrind.
  96 * dev-util/meson for integration with the Meson build system.
  97 * dev-util/cargo for integration with the Rust Cargo build system.
  98 * dev-util/cmake for integration with the CMake build system.
  99 * net-libs/nodejs[npm] for integration with the NPM package system.
 100 '
 101 # FIXME: Package gnome-code-assistance and mention here, or maybe USE flag and default enable because it's rather important
 102 # eslint for additional diagnostics in JavaScript files (what package has this? At least something via NPM..)
 103 # jhbuild support
 104 # rust language server via rls; Go via go-langserver
 105 # autotools stuff for autotools plugin; gtkmm/autoconf-archive for C++ template
 106 # gjs/gettext/mono/PHPize stuff, but most of these are probably installed for other reasons anyways, when needed inside IDE
 107
 108 PATCHES=(
 109         "${WORKDIR}/patches" # gnome-builder-3-32 branch 2020-01-14 (commit 325cfb6d9e4) + cherry-picked meson link_whole fixes
 110         "${FILESDIR}"/${PV}-optional-vala.patch
 111 )
 112
 113 llvm_check_deps() {
 114         has_version "sys-devel/clang:${LLVM_SLOT}"
 115 }
 116
 117 pkg_setup() {
 118         python-single-r1_pkg_setup
 119         use clang && llvm_pkg_setup
 120 }
 121
 122 src_prepare() {
 123         use vala && vala_src_prepare
 124         xdg_src_prepare
 125 }
 126
 127 src_configure() {
 128         local emesonargs=(
 129                 -Dtracing=false
 130                 -Dprofiling=false # not passing -pg to CFLAGS
 131                 -Dfusermount_wrapper=false # meant for flatpak builds
 132                 -Dtcmalloc=false
 133                 -Dchannel=other
 134
 135                 $(meson_use vala vapi) # TODO: doesn't work anymore; crude patch included
 136                 $(meson_use doc help)
 137                 $(meson_use gtk-doc docs)
 138
 139                 -Dnetwork_tests=false
 140                 $(meson_use clang plugin_clang)
 141                 $(meson_use devhelp plugin_devhelp)
 142                 -Dplugin_deviced=false
 143                 -Dplugin_editorconfig=true # needs libpcre
 144                 -Dplugin_flatpak=false
 145                 -Dplugin_podman=false
 146                 $(meson_use glade plugin_glade)
 147                 -Dplugin_git=true
 148                 $(meson_use spell plugin_spellcheck)
 149                 $(meson_use sysprof plugin_sysprof)
 150                 $(meson_use vala plugin_vala)
 151         )
 152         meson_src_configure
 153 }
 154
 155 src_install() {
 156         meson_src_install
 157         python_optimize
 158         if use doc; then
 159                 rm "${ED}"/usr/share/doc/gnome-builder/en/.buildinfo || die
 160                 rm "${ED}"/usr/share/doc/gnome-builder/en/objects.inv || die
 161                 rm -r "${ED}"/usr/share/doc/gnome-builder/en/.doctrees || die
 162                 # custom docdir in build system, blocked by https://github.com/mesonbuild/meson/issues/825
 163                 mv "${ED}"/usr/share/doc/gnome-builder/en "${ED}"/usr/share/doc/${PF}/html || die
 164                 # _sources subdir left in on purpose, as HTML links to the rst files as "View page source". Additionally default docompress exclusion of /html/ already ensures they aren't compressed, thus linkable as-is.
 165                 rmdir "${ED}"/usr/share/doc/gnome-builder/ || die
 166         fi
 167         readme.gentoo_create_doc
 168 }
 169
 170 pkg_postinst() {
 171         xdg_pkg_postinst
 172         gnome2_schemas_update
 173         readme.gentoo_print_elog
 174 }
 175
 176 pkg_postrm() {
 177         xdg_pkg_postrm
 178         gnome2_schemas_update
 179 }
 180
 181 src_test() {
 182         # FIXME: can't run meson_src_test together with virtx or dbus-run-session
 183         virtx dbus-run-session meson test -C "${BUILD_DIR}"
 184 }